source: Deliverables/D2.2/8051-indexed-labels-branch/src/clight/clightPrinter.ml @ 1291

Last change on this file since 1291 was 1291, checked in by tranquil, 9 years ago

Started branch of untrusted compiler with indexed labels

  • added indexing structure to CostLabel?
  • propagated changes to other modules
  • added indexing as parameter to labelling
  • loop indexes not implemented yet, so behaviour is still the same
File size: 16.7 KB
Line 
1(* *********************************************************************)
2(*                                                                     *)
3(*              The Compcert verified compiler                         *)
4(*                                                                     *)
5(*          Xavier Leroy, INRIA Paris-Rocquencourt                     *)
6(*                                                                     *)
7(*  Copyright Institut National de Recherche en Informatique et en     *)
8(*  Automatique.  All rights reserved.  This file is distributed       *)
9(*  under the terms of the GNU General Public License as published by  *)
10(*  the Free Software Foundation, either version 2 of the License, or  *)
11(*  (at your option) any later version.  This file is also distributed *)
12(*  under the terms of the INRIA Non-Commercial License Agreement.     *)
13(*                                                                     *)
14(* *********************************************************************)
15
16(** Pretty-printer for Csyntax *)
17
18open Format
19open AST
20open Clight
21
22let name_unop = function
23  | Onotbool -> "!"
24  | Onotint  -> "~"
25  | Oneg     -> "-"
26
27
28let name_binop = function
29  | Oadd -> "+"
30  | Osub -> "-"
31  | Omul -> "*"
32  | Odiv -> "/"
33  | Omod -> "%"
34  | Oand -> "&"
35  | Oor  -> "|"
36  | Oxor -> "^"
37  | Oshl -> "<<"
38  | Oshr -> ">>"
39  | Oeq  -> "=="
40  | One  -> "!="
41  | Olt  -> "<"
42  | Ogt  -> ">"
43  | Ole  -> "<="
44  | Oge  -> ">="
45
46let name_inttype sz sg =
47  match sz, sg with
48  | I8, Signed -> "signed char"
49  | I8, Unsigned -> "unsigned char"
50  | I16, Signed -> "short"
51  | I16, Unsigned -> "unsigned short"
52  | I32, Signed -> "int"
53  | I32, Unsigned -> "unsigned int"
54
55let name_floattype sz =
56  match sz with
57  | F32 -> "float"
58  | F64 -> "double"
59
60(* Collecting the names and fields of structs and unions *)
61
62module StructUnionSet = Set.Make(struct
63  type t = string * (ident*ctype) list
64  let compare (n1, _ : t) (n2, _ : t) = compare n1 n2
65end)
66
67let struct_unions = ref StructUnionSet.empty
68
69let register_struct_union id fld =
70  struct_unions := StructUnionSet.add (id, fld) !struct_unions
71
72(* Declarator (identifier + type) *)
73
74let name_optid id =
75  if id = "" then "" else " " ^ id
76
77let parenthesize_if_pointer id =
78  if String.length id > 0 && id.[0] = '*' then "(" ^ id ^ ")" else id
79
80let rec name_cdecl id ty =
81  match ty with
82  | Tvoid ->
83      "void" ^ name_optid id
84  | Tint(sz, sg) ->
85      name_inttype sz sg ^ name_optid id
86  | Tfloat sz ->
87      name_floattype sz ^ name_optid id
88  | Tpointer t ->
89      name_cdecl ("*" ^ id) t
90  | Tarray(t, n) ->
91      name_cdecl
92        (sprintf "%s[%ld]" (parenthesize_if_pointer id) (Int32.of_int n))
93        t
94  | Tfunction(args, res) ->
95      let b = Buffer.create 20 in
96      if id = ""
97      then Buffer.add_string b "(*)"
98      else Buffer.add_string b (parenthesize_if_pointer id);
99      Buffer.add_char b '(';
100      begin match args with
101      | [] ->
102          Buffer.add_string b "void"
103      | _ ->
104          let rec add_args first = function
105          | [] -> ()
106          | t1::tl ->
107              if not first then Buffer.add_string b ", ";
108              Buffer.add_string b (name_cdecl "" t1);
109              add_args false tl in
110          add_args true args
111      end;
112      Buffer.add_char b ')';
113      name_cdecl (Buffer.contents b) res
114  | Tstruct(name, fld) ->
115      name ^ name_optid id
116  | Tunion(name, fld) ->
117      name ^ name_optid id
118  | Tcomp_ptr name ->
119      name ^ " *" ^ id
120
121(* Type *)
122
123let name_type ty = name_cdecl "" ty
124
125(* Expressions *)
126
127let parenthesis_level (Expr (e, ty)) =
128  match e with
129  | Econst_int _ -> 0
130  | Econst_float _ -> 0
131  | Evar _ -> 0
132  | Eunop(_, _) -> 30
133  | Ederef _ -> 20
134  | Eaddrof _ -> 30
135  | Ebinop(op, _, _) ->
136      begin match op with
137      | Oand | Oor | Oxor -> 75
138      | Oeq | One | Olt | Ogt | Ole | Oge -> 70
139      | Oadd | Osub | Oshl | Oshr -> 60
140      | Omul | Odiv | Omod -> 40
141      end
142  | Ecast _ -> 30
143  | Econdition(_, _, _) -> 80
144  | Eandbool(_, _) -> 80
145  | Eorbool(_, _) -> 80
146  | Esizeof _ -> 20
147  | Efield _ -> 20
148  | Ecost (_,_) -> 20 
149  | Ecall (_,_,_) -> 20
150
151let rec print_expr p (Expr (eb, ty) as e) =
152  let level = parenthesis_level e in
153  match eb with
154  | Econst_int n ->
155      fprintf p "%ld" (Int32.of_int n)
156  | Econst_float f ->
157      fprintf p "%F" f
158  | Evar id ->
159      fprintf p "%s" id
160  | Eunop(op, e1) ->
161      fprintf p "%s%a" (name_unop op) print_expr_prec (level, e1)
162  | Ederef (Expr (Ebinop(Oadd, e1, e2), _)) ->
163      fprintf p "@[<hov 2>%a@,[%a]@]"
164                print_expr_prec (level, e1)
165                print_expr_prec (level, e2)
166  | Ederef (Expr (Efield(e1, id), _)) ->
167      fprintf p "%a->%s" print_expr_prec (level, e1) id
168  | Ederef e ->
169      fprintf p "*%a" print_expr_prec (level, e)
170  | Eaddrof e ->
171      fprintf p "&%a" print_expr_prec (level, e)
172  | Ebinop(op, e1, e2) ->
173      fprintf p "@[<hov 0>%a@ %s %a@]"
174                print_expr_prec (level, e1)
175                (name_binop op)
176                print_expr_prec (level, e2)
177  | Ecast(ty, e1) ->
178      fprintf p "@[<hov 2>(%s)@,%a@]"
179                (name_type ty)
180                print_expr_prec (level, e1)
181  | Econdition(e1, e2, e3) ->
182      fprintf p "@[<hov 0>%a@ ? %a@ : %a@]"
183                print_expr_prec (level, e1)
184                print_expr_prec (level, e2)
185                print_expr_prec (level, e3)
186  | Eandbool(e1, e2) ->
187      fprintf p "@[<hov 0>%a@ && %a@]"
188                print_expr_prec (level, e1)
189                print_expr_prec (level, e2)
190  | Eorbool(e1, e2) ->
191      fprintf p "@[<hov 0>%a@ || %a@]"
192                print_expr_prec (level, e1)
193                print_expr_prec (level, e2)
194  | Esizeof ty ->
195      fprintf p "sizeof(%s)" (name_type ty)
196  | Efield(e1, id) ->
197      fprintf p "%a.%s" print_expr_prec (level, e1) id
198  | Ecost(lbl, e1) ->
199                  (* printing label uglily even if in comment for consistence *)
200                  let lbl = CostLabel.string_of_cost_label lbl in
201                        fprintf p "(/* %s */ %a)" lbl print_expr e1
202  | Ecall(f, arg, e) ->
203      fprintf p "(%s(%a), %a)" f print_expr arg print_expr e
204
205and print_expr_prec p (context_prec, e) =
206  let this_prec = parenthesis_level e in
207  if this_prec >= context_prec
208  then fprintf p "(%a)" print_expr e
209  else print_expr p e
210
211let rec print_expr_list p (first, el) =
212  match el with
213  | [] -> ()
214  | e1 :: et ->
215      if not first then fprintf p ",@ ";
216      print_expr p e1;
217      print_expr_list p (false, et)
218
219let rec print_stmt p s =
220  match s with
221  | Sskip ->
222      fprintf p "/*skip*/;"
223  | Sassign(e1, e2) ->
224      fprintf p "@[<hv 2>%a =@ %a;@]" print_expr e1 print_expr e2
225  | Scall(None, e1, el) ->
226      fprintf p "@[<hv 2>%a@,(@[<hov 0>%a@]);@]"
227                print_expr e1
228                print_expr_list (true, el)
229  | Scall(Some lhs, e1, el) ->
230      fprintf p "@[<hv 2>%a =@ %a@,(@[<hov 0>%a@]);@]"
231                print_expr lhs
232                print_expr e1
233                print_expr_list (true, el)
234  | Ssequence(s1, s2) ->
235      fprintf p "%a@ %a" print_stmt s1 print_stmt s2
236  | Sifthenelse(e, s1, Sskip) ->
237      fprintf p "@[<v 2>if (%a) {@ %a@;<0 -2>}@]"
238              print_expr e
239              print_stmt s1
240  | Sifthenelse(e, s1, s2) ->
241      fprintf p "@[<v 2>if (%a) {@ %a@;<0 -2>} else {@ %a@;<0 -2>}@]"
242              print_expr e
243              print_stmt s1
244              print_stmt s2
245  | Swhile(e, s) ->
246      fprintf p "@[<v 2>while (%a) {@ %a@;<0 -2>}@]"
247              print_expr e
248              print_stmt s
249  | Sdowhile(e, s) ->
250      fprintf p "@[<v 2>do {@ %a@;<0 -2>} while(%a);@]"
251              print_stmt s
252              print_expr e
253  | Sfor(s_init, e, s_iter, s_body) ->
254      fprintf p "@[<v 2>for (@[<hv 0>%a;@ %a;@ %a) {@]@ %a@;<0 -2>}@]"
255              print_stmt_for s_init
256              print_expr e
257              print_stmt_for s_iter
258              print_stmt s_body
259  | Sbreak ->
260      fprintf p "break;"
261  | Scontinue ->
262      fprintf p "continue;"
263  | Sswitch(e, cases) ->
264      fprintf p "@[<v 2>switch (%a) {@ %a@;<0 -2>}@]"
265              print_expr e
266              print_cases cases
267  | Sreturn None ->
268      fprintf p "return;"
269  | Sreturn (Some e) ->
270      fprintf p "return %a;" print_expr e
271  | Slabel(lbl, s1) ->
272      fprintf p "%s:@ %a" lbl print_stmt s1
273  | Sgoto lbl ->
274      fprintf p "goto %s;" lbl
275 | Scost (lbl,s1) ->
276           let lbl = CostLabel.string_of_cost_label lbl in
277     fprintf p "%s:@ %a" lbl print_stmt s1
278
279and print_cases p cases =
280  match cases with
281  | LSdefault Sskip ->
282      ()
283  | LSdefault s ->
284      fprintf p "@[<v 2>default:@ %a@]" print_stmt s
285  | LScase(lbl, Sskip, rem) ->
286      fprintf p "case %ld:@ %a"
287        (Int32.of_int lbl)
288        print_cases rem
289  | LScase(lbl, s, rem) ->
290      fprintf p "@[<v 2>case %ld:@ %a@]@ %a"
291              (Int32.of_int lbl)
292              print_stmt s
293              print_cases rem
294
295and print_stmt_for p s =
296  match s with
297  | Sskip ->
298      fprintf p "/*nothing*/"
299  | Sassign(e1, e2) ->
300      fprintf p "%a = %a" print_expr e1 print_expr e2
301  | Ssequence(s1, s2) ->
302      fprintf p "%a, %a" print_stmt_for s1 print_stmt_for s2
303  | Scall(None, e1, el) ->
304      fprintf p "@[<hv 2>%a@,(@[<hov 0>%a@])@]"
305                print_expr e1
306                print_expr_list (true, el)
307  | Scall(Some lhs, e1, el) ->
308      fprintf p "@[<hv 2>%a =@ %a@,(@[<hov 0>%a@])@]"
309                print_expr lhs
310                print_expr e1
311                print_expr_list (true, el)
312  | _ ->
313      fprintf p "({ %a })" print_stmt s
314
315let name_function_parameters fun_name params =
316  let b = Buffer.create 20 in
317  Buffer.add_string b fun_name;
318  Buffer.add_char b '(';
319  begin match params with
320  | [] ->
321      Buffer.add_string b "void"
322  | _ ->
323      let rec add_params first = function
324      | [] -> ()
325      | (id, ty) :: rem ->
326          if not first then Buffer.add_string b ", ";
327          Buffer.add_string b (name_cdecl id ty);
328          add_params false rem in
329      add_params true params
330  end;
331  Buffer.add_char b ')';
332  Buffer.contents b
333
334let print_function p id f =
335  fprintf p "%s@ "
336            (name_cdecl (name_function_parameters id f.fn_params)
337                        f.fn_return);
338  fprintf p "@[<v 2>{@ ";
339  List.iter
340    (fun ((id, ty)) ->
341      fprintf p "%s;@ " (name_cdecl id ty))
342    f.fn_vars;
343  print_stmt p f.fn_body;
344  fprintf p "@;<0 -2>}@]@ @ "
345
346let print_fundef p (id, fd) =
347  match fd with
348  | External(_, args, res) ->
349      fprintf p "extern %s;@ @ "
350                (name_cdecl id (Tfunction(args, res)))
351  | Internal f ->
352      print_function p id f
353
354let string_of_init id =
355  let b = Buffer.create (List.length id) in
356  let add_init = function
357  | Init_int8 n ->
358      if n >= 32 && n <= 126 && n <> Char.code '\"' && n <> Char.code '\\'
359      then Buffer.add_char b (Char.chr n)
360      else Buffer.add_string b (Printf.sprintf "\\%03o" n)
361  | _ ->
362      assert false
363  in List.iter add_init id; Buffer.contents b
364
365let chop_last_nul id =
366  match List.rev id with
367  | Init_int8 0 :: tl -> List.rev tl
368  | _ -> id
369
370let print_init p = function
371  | Init_int8 n -> fprintf p "%ld,@ " (Int32.of_int n)
372  | Init_int16 n -> fprintf p "%ld,@ " (Int32.of_int n)
373  | Init_int32 n -> fprintf p "%ld,@ " (Int32.of_int n)
374  | Init_float32 n -> fprintf p "%F,@ " n
375  | Init_float64 n -> fprintf p "%F,@ " n
376  | Init_space n -> fprintf p "/* skip %ld, */@ " (Int32.of_int n)
377  | Init_addrof(symb, ofs) ->
378      let ofs = Int32.of_int ofs in
379      if ofs = Int32.zero
380      then fprintf p "&%s,@ " symb
381      else fprintf p "(void *)((char *)&%s + %ld),@ " symb ofs
382
383let print_init1 p = function
384  | Init_int8 n -> fprintf p "%ld" (Int32.of_int n)
385  | Init_int16 n -> fprintf p "%ld" (Int32.of_int n)
386  | Init_int32 n -> fprintf p "%ld" (Int32.of_int n)
387  | Init_float32 n -> fprintf p "%F" n
388  | Init_float64 n -> fprintf p "%F" n
389  | Init_space n -> fprintf p "/* skip %ld */" (Int32.of_int n)
390  | Init_addrof(symb, ofs) ->
391      let ofs = Int32.of_int ofs in
392      if ofs = Int32.zero
393      then fprintf p "&%s" symb
394      else fprintf p "(void *)((char *)&%s + %ld)" symb ofs
395
396let re_string_literal = Str.regexp "__stringlit_[0-9]+"
397
398let print_globvar p (((id, init), ty)) =
399  match init with
400  | [] ->
401      fprintf p "extern %s;@ @ "
402              (name_cdecl id ty)
403  | [Init_space _] ->
404      fprintf p "%s;@ @ "
405              (name_cdecl id ty)
406  | [init] ->
407      fprintf p "@[<hov 2>%s = %a;@]@ @ "
408              (name_cdecl id ty) print_init1 init
409  | _ ->
410      fprintf p "@[<hov 2>%s = "
411              (name_cdecl id ty);
412      if Str.string_match re_string_literal id 0
413      && List.for_all (function Init_int8 _ -> true | _ -> false) init
414      then
415        fprintf p "\"%s\"" (string_of_init (chop_last_nul init))
416      else begin
417        fprintf p "{@ ";
418        List.iter (print_init p) init;
419        fprintf p "}"
420      end;
421      fprintf p ";@]@ @ "
422
423(* Collect struct and union types *)
424
425let rec collect_type = function
426  | Tvoid -> ()
427  | Tint(sz, sg) -> ()
428  | Tfloat sz -> ()
429  | Tpointer t -> collect_type t
430  | Tarray(t, n) -> collect_type t
431  | Tfunction(args, res) -> collect_type_list args; collect_type res
432  | Tstruct(id, fld) -> register_struct_union id fld; collect_fields fld
433  | Tunion(id, fld) -> register_struct_union id fld; collect_fields fld
434  | Tcomp_ptr _ -> ()
435
436and collect_type_list = function
437  | [] -> ()
438  | hd::tl -> collect_type hd; collect_type_list tl
439
440and collect_fields = function
441  | [] -> ()
442  | (id, hd)::tl -> collect_type hd; collect_fields tl
443
444let rec collect_expr (Expr(ed, ty)) =
445  match ed with
446  | Econst_int n -> ()
447  | Econst_float f -> ()
448  | Evar id -> ()
449  | Eunop(op, e1) -> collect_expr e1
450  | Ederef e -> collect_expr e
451  | Eaddrof e -> collect_expr e
452  | Ebinop(op, e1, e2) -> collect_expr e1; collect_expr e2
453  | Ecast(ty, e1) -> collect_type ty; collect_expr e1
454  | Econdition(e1, e2, e3) -> collect_expr e1; collect_expr e2; collect_expr e3
455  | Eandbool(e1, e2) -> collect_expr e1; collect_expr e2
456  | Eorbool(e1, e2) -> collect_expr e1; collect_expr e2
457  | Esizeof ty -> collect_type ty
458  | Efield(e1, id) -> collect_expr e1
459  | Ecost(_, e) -> collect_expr e
460  | Ecall(_, arg, e) -> collect_expr arg; collect_expr e
461
462let rec collect_expr_list = function
463  | [] -> ()
464  | hd :: tl -> collect_expr hd; collect_expr_list tl
465
466let rec collect_stmt = function
467  | Sskip -> ()
468  | Sassign(e1, e2) -> collect_expr e1; collect_expr e2
469  | Scall(None, e1, el) -> collect_expr e1; collect_expr_list el
470  | Scall(Some lhs, e1, el) -> collect_expr lhs; collect_expr e1; collect_expr_list el
471  | Ssequence(s1, s2) -> collect_stmt s1; collect_stmt s2
472  | Sifthenelse(e, s1, s2) -> collect_expr e; collect_stmt s1; collect_stmt s2
473  | Swhile(e, s) -> collect_expr e; collect_stmt s
474  | Sdowhile(e, s) -> collect_stmt s; collect_expr e
475  | Sfor(s_init, e, s_iter, s_body) ->
476      collect_stmt s_init; collect_expr e;
477      collect_stmt s_iter; collect_stmt s_body
478  | Sbreak -> ()
479  | Scontinue -> ()
480  | Sswitch(e, cases) -> collect_expr e; collect_cases cases
481  | Sreturn None -> ()
482  | Sreturn (Some e) -> collect_expr e
483  | Slabel(lbl, s) -> collect_stmt s
484  | Sgoto lbl -> ()
485  | Scost (_,s1) -> collect_stmt s1
486
487and collect_cases = function
488  | LSdefault s -> collect_stmt s
489  | LScase(lbl, s, rem) -> collect_stmt s; collect_cases rem
490
491let collect_function f =
492  collect_type f.fn_return;
493  List.iter (fun ((id, ty)) -> collect_type ty) f.fn_params;
494  List.iter (fun ((id, ty)) -> collect_type ty) f.fn_vars;
495  collect_stmt f.fn_body
496
497let collect_fundef ((id, fd)) =
498  match fd with
499  | External(_, args, res) -> collect_type_list args; collect_type res
500  | Internal f -> collect_function f
501
502let collect_globvar (((id, init), ty)) =
503  collect_type ty
504
505let collect_program p =
506  List.iter collect_globvar p.prog_vars;
507  List.iter collect_fundef p.prog_funct
508
509let declare_struct_or_union p (name, fld) =
510  fprintf p "%s;@ @ " name
511
512let print_struct_or_union p (name, fld) =
513  fprintf p "@[<v 2>%s {" name;
514  let rec print_fields = function
515  | [] -> ()
516  | (id, ty)::rem ->
517      fprintf p "@ %s;" (name_cdecl id ty);
518      print_fields rem in
519  print_fields fld;
520  fprintf p "@;<0 -2>};@]@ "
521
522let print_program_2 p prog =
523  struct_unions := StructUnionSet.empty;
524  collect_program prog;
525  fprintf p "@[<v 0>";
526  StructUnionSet.iter (declare_struct_or_union p) !struct_unions;
527  StructUnionSet.iter (print_struct_or_union p) !struct_unions;
528  List.iter (print_globvar p) prog.prog_vars;
529  List.iter (print_fundef p) prog.prog_funct;
530  fprintf p "@]@."
531
532let print_program prog =
533  print_program_2 str_formatter prog;
534  flush_str_formatter ()
535
536let string_of_ctype = name_type
537
538let print_expression e = 
539  print_expr str_formatter e;
540  flush_str_formatter ()
541
542let print_statement s = 
543  print_stmt str_formatter s;
544  flush_str_formatter ()
545
546let print_ctype_prot = name_type
547
548let print_ctype_def = function
549  | Tstruct (name, fld) | Tunion (name, fld) ->
550    let f_fld s (id, t) = s ^ "  " ^ (print_ctype_prot t) ^ " " ^ id ^ ";\n" in
551    let s_fld = List.fold_left f_fld "" in
552    name ^ " {\n" ^ (s_fld fld) ^ "};\n"
553  | _ -> "" (* no definition associated to the other types *)
Note: See TracBrowser for help on using the repository browser.