source: Deliverables/D2.2/8051-indexed-labels-branch/src/clight/clightInterpret.ml @ 1334

Last change on this file since 1334 was 1334, checked in by tranquil, 8 years ago

work on Cminor completed

File size: 22.4 KB
Line 
1module Mem = Driver.ClightMemory
2module Value = Driver.ClightMemory.Value
3module LocalEnv = Map.Make(String)
4type localEnv = Value.address LocalEnv.t
5type memory = Clight.fundef Mem.memory
6type indexing = CostLabel.const_indexing
7
8open Clight
9open AST
10
11
12let error_prefix = "Clight interpret"
13let error s = Error.global_error error_prefix s
14let warning s = Error.warning error_prefix s
15let error_float () = error "float not supported."
16
17
18(* Helpers *)
19
20let value_of_address = List.hd
21let address_of_value v = [v]
22
23
24(* State of execution *)
25
26type continuation =
27  | Kstop
28  | Kseq of statement*continuation
29  | Kwhile of int option*expr*statement*continuation
30  | Kdowhile of int option*expr*statement*continuation
31  | Kfor2 of int option*expr*statement*statement*continuation
32  | Kfor3 of int option*expr*statement*statement*continuation
33  | Kswitch of continuation
34  | Kcall of (Value.address*ctype) option*cfunction*localEnv*
35        indexing*continuation
36
37type state =
38  | State of cfunction*statement*continuation*localEnv*memory*indexing
39  | Callstate of fundef*Value.t list*continuation*memory
40  | Returnstate of Value.t*continuation*memory
41
42let string_of_unop = function
43  | Onotbool -> "!"
44  | Onotint -> "~"
45  | Oneg -> "-"
46
47let string_of_binop = function
48  | Oadd -> "+"
49  | Osub -> "-"
50  | Omul -> "*"
51  | Odiv -> "/"
52  | Omod -> "%"
53  | Oand -> "&"
54  | Oor  -> "|"
55  | Oxor -> "^"
56  | Oshl -> "<<"
57  | Oshr -> ">>"
58  | Oeq -> "=="
59  | One -> "!="
60  | Olt -> "<"
61  | Ogt -> ">"
62  | Ole -> "<="
63  | Oge -> ">="
64
65let string_of_signedness = function
66  | Signed -> "signed"
67  | Unsigned -> "unsigned"
68
69let string_of_sized_int = function
70  | I8 -> "char"
71  | I16 -> "short"
72  | I32 -> "int"
73
74let rec string_of_ctype = function
75  | Tvoid -> "void"
76  | Tint (size, sign) ->
77    (string_of_signedness sign) ^ " " ^ (string_of_sized_int size)
78  | Tfloat _ -> error_float ()
79  | Tpointer ty -> (string_of_ctype ty) ^ "*"
80  | Tarray (ty, _) -> (string_of_ctype ty) ^ "[]"
81  | Tfunction _ -> assert false (* do not cast to a function type *)
82  | Tstruct (id, _)
83  | Tunion (id, _) -> id
84  | Tcomp_ptr id -> id ^ "*"
85
86let rec string_of_expr (Expr (e, _)) = string_of_expr_descr e
87and string_of_expr_descr = function
88  | Econst_int i -> string_of_int i
89  | Econst_float _ -> error_float ()
90  | Evar x -> x
91  | Ederef e -> "*(" ^ (string_of_expr e) ^ ")"
92  | Eaddrof e -> "&(" ^ (string_of_expr e) ^ ")"
93  | Eunop (unop, e) -> (string_of_unop unop) ^ "(" ^ (string_of_expr e) ^ ")"
94  | Ebinop (binop, e1, e2) ->
95    "(" ^ (string_of_expr e1) ^ ")" ^ (string_of_binop binop) ^
96    "(" ^ (string_of_expr e2) ^ ")"
97  | Ecast (ty, e) ->
98    "(" ^ (string_of_ctype ty) ^ ") (" ^ (string_of_expr e) ^ ")"
99  | Econdition (e1, e2, e3) ->
100    "(" ^ (string_of_expr e1) ^ ") ? (" ^ (string_of_expr e2) ^
101    ") : (" ^ (string_of_expr e3) ^ ")"
102  | Eandbool (e1, e2) ->
103    "(" ^ (string_of_expr e1) ^ ") && (" ^ (string_of_expr e2) ^ ")"
104  | Eorbool (e1, e2) ->
105    "(" ^ (string_of_expr e1) ^ ") || (" ^ (string_of_expr e2) ^ ")"
106  | Esizeof ty -> "sizeof(" ^ (string_of_ctype ty) ^ ")"
107  | Efield (e, field) -> "(" ^ (string_of_expr e) ^ ")." ^ field
108  | Ecost (cost_lbl, e) -> 
109                let cost_lbl = CostLabel.string_of_cost_label cost_lbl in
110                "/* " ^ cost_lbl ^ " */ " ^ (string_of_expr e)
111  | Ecall (f, arg, e) ->
112    "(" ^ f ^ "(" ^ (string_of_expr arg) ^ "), " ^ (string_of_expr e) ^ ")"
113
114let string_of_args args =
115  "(" ^ (MiscPottier.string_of_list ", " string_of_expr args) ^ ")"
116
117let string_of_loop_depth = function
118        | None -> ""
119        | Some d -> " at " ^ string_of_int d
120
121let rec string_of_statement = function
122  | Sskip -> "skip"
123  | Sassign (e1, e2) -> (string_of_expr e1) ^ " = " ^ (string_of_expr e2)
124  | Scall (None, f, args) -> (string_of_expr f) ^ (string_of_args args)
125  | Scall (Some e, f, args) ->
126    (string_of_expr e) ^ " = " ^ (string_of_expr f) ^ (string_of_args args)
127  | Ssequence _ -> "sequence"
128  | Sifthenelse (e, _, _) -> "if (" ^ (string_of_expr e) ^ ")"
129  | Swhile (i, e, _) ->
130                let d = string_of_loop_depth i in
131                "while" ^ d ^ " (" ^ (string_of_expr e) ^ ")"
132  | Sdowhile (i, _, _) ->
133    let d = string_of_loop_depth i in
134    "dowhile" ^ d
135  | Sfor (i, s, _, _, _) ->
136                let d = string_of_loop_depth i in
137                "for" ^ d ^ " (" ^ (string_of_statement s) ^ "; ...)"
138  | Sbreak -> "break"
139  | Scontinue -> "continue"
140  | Sreturn None -> "return"
141  | Sreturn (Some e) -> "return (" ^ (string_of_expr e) ^ ")"
142  | Sswitch (e, _) -> "switch (" ^ (string_of_expr e) ^ ")"
143  | Slabel (lbl, _) -> "label " ^ lbl
144  | Sgoto lbl -> "goto " ^ lbl
145  | Scost (lbl, _) ->
146    let lbl = CostLabel.string_of_cost_label lbl in
147                "cost " ^ lbl
148
149let string_of_local_env lenv =
150  let f x addr s =
151    s ^ x ^ " = " ^ (Value.to_string (value_of_address addr)) ^ "  " in
152  LocalEnv.fold f lenv ""
153
154let print_state state = (match state with
155  | State (_, stmt, _, lenv, mem, c) ->
156    Printf.printf "Local environment:\n%s\n\nMemory:%s\nLoop indexing: "
157      (string_of_local_env lenv)
158      (Mem.to_string mem);
159                Array.iteri (fun a -> Printf.printf "%d,") c;
160    Printf.printf "\nRegular state: %s\n\n%!"
161      (string_of_statement stmt)
162  | Callstate (_, args, _, mem) ->
163    Printf.printf "Memory:%s\nCall state\n\nArguments:\n%s\n\n%!"
164      (Mem.to_string mem)
165      (MiscPottier.string_of_list " " Value.to_string args)
166  | Returnstate (v, _, mem) ->
167    Printf.printf "Memory:%s\nReturn state: %s\n\n%!"
168      (Mem.to_string mem)
169      (Value.to_string v)
170        ); Printf.printf "---------------------------------------------------------\n"
171
172
173(* Continuations and labels *)
174
175let rec call_cont = function
176  | Kseq (_,k) | Kwhile (_, _,_,k) | Kdowhile (_, _,_,k)
177  | Kfor2 (_, _,_,_,k) | Kfor3 (_, _,_,_,k) | Kswitch k -> call_cont k
178  | k -> k
179
180let rec seq_of_labeled_statement = function
181  | LSdefault s -> s
182  | LScase (c,s,sl') -> Ssequence (s,(seq_of_labeled_statement sl'))
183
184let rec find_label1 lbl s k = match s with
185   | Ssequence (s1,s2) ->
186      (match find_label1 lbl s1 (Kseq (s2,k)) with
187      | Some sk -> Some sk
188      | None -> find_label1 lbl s2 k
189      )
190  | Sifthenelse (a,s1,s2) ->
191      (match find_label1 lbl s1 k with
192      | Some sk -> Some sk
193      | None -> find_label1 lbl s2 k
194      )
195  | Swhile (i,a,s1) -> find_label1 lbl s1 (Kwhile(i,a,s1,k))
196  | Sdowhile (i,a,s1) -> find_label1 lbl s1 (Kdowhile(i,a,s1,k))
197  | Sfor (i,a1,a2,a3,s1) ->
198                (* doubt: should we search for labels in a1? *)
199      (match find_label1 lbl a1 (Kseq ((Sfor(i,Sskip,a2,a3,s1)),k)) with
200      | Some sk -> Some sk
201      | None ->
202          (match find_label1 lbl s1 (Kfor2(i,a2,a3,s1,k)) with
203          | Some sk -> Some sk
204          | None -> find_label1 lbl a3 (Kfor3(i,a2,a3,s1,k))
205          ))
206  | Sswitch (e,sl) -> find_label_ls lbl sl (Kswitch k)
207  | Slabel (lbl',s') -> if lbl=lbl' then Some(s', k) else find_label1 lbl s' k
208  | Scost (_,s') -> find_label1 lbl s' k
209  | Sskip | Sassign (_,_) | Scall (_,_,_) | Sbreak 
210  | Scontinue | Sreturn _ | Sgoto _ -> None
211           
212and find_label_ls lbl sl k =  match sl with
213  | LSdefault s -> find_label1 lbl s k
214  | LScase (_,s,sl') ->
215      (match find_label1 lbl s (Kseq((seq_of_labeled_statement sl'),k)) with
216      | Some sk -> Some sk
217      | None -> find_label_ls lbl sl' k
218      )
219
220let find_label lbl s k = match find_label1 lbl s k with
221  | Some res -> res
222  | _ -> assert false (* should be impossible *)
223
224let rec select_switch i = function
225  | LSdefault d -> LSdefault d
226  | LScase (c,s,sl') when c=i-> LScase (c,s,sl') 
227  | LScase (_,_,sl') -> select_switch i sl'
228
229
230(* ctype functions *)
231
232let sizeof ctype = Mem.concrete_size (ClightToCminor.sizeof_ctype ctype)
233
234let size_of_ctype = function
235  | Tint (I8, _)  -> 1
236  | Tint (I16, _) -> 2
237  | Tint (I32, _) -> 4
238  | Tfloat _ -> error_float ()
239  | Tcomp_ptr _
240  | Tpointer _
241  | Tarray _
242  | Tstruct _
243  | Tunion _ -> Mem.ptr_size
244  | _ -> assert false (* do not use on these arguments *)
245
246let is_function_type = function
247  | Tfunction _ -> true
248  | _ -> false
249
250let is_array_type = function
251  | Tarray _ -> true
252  | _ -> false
253
254let is_complex_type = function
255  | Tstruct _ | Tunion _ -> true
256  | _ -> false
257
258let is_big_type t = (is_array_type t) || (is_complex_type t)
259
260let dest_type = function
261  | Tpointer ty | Tarray (ty, _) -> ty
262  | _ -> assert false (* do not use on these arguments *)
263
264
265(* Global and local environment management *)
266
267let find_local x lenv =
268  if LocalEnv.mem x lenv then LocalEnv.find x lenv
269  else error ("Unknown local variable " ^ x ^ ".")
270
271let find_global x mem =
272  if Mem.mem_global mem x then Mem.find_global mem x
273  else error ("Unknown global variable " ^ x ^ ".")
274
275let find_symbol lenv mem x =
276  if LocalEnv.mem x lenv then LocalEnv.find x lenv
277  else
278    if Mem.mem_global mem x then Mem.find_global mem x
279    else error ("Unknown variable " ^ x ^ ".")
280
281let find_fundef f mem =
282  let addr = Mem.find_global mem f in
283  Mem.find_fun_def mem addr
284
285
286(* Interpret *)
287
288let byte_of_intsize = function
289  | I8 -> 1
290  | I16 -> 2
291  | I32 -> 4
292
293let choose_cast sign n m v =
294  let f = match sign with
295    | Signed -> Value.sign_ext
296    | Unsigned -> Value.zero_ext in
297  f v n m
298
299let eval_cast = function
300  (* Cast Integer *)
301  | (v,Tint(isize,sign),Tint(isize',_)) ->
302    choose_cast sign (byte_of_intsize isize) (byte_of_intsize isize') v
303  | (v,_,_) -> v
304
305let to_int32 (v, t) = eval_cast (v, t, Tint (I32, Signed))
306
307let eval_unop ret_ctype ((_, t) as e) op =
308  let v = to_int32 e in
309  let v = match op with
310    | Onotbool -> Value.notbool v
311    | Onotint -> Value.notint v
312    | Oneg -> Value.negint v in
313  eval_cast (v, t, ret_ctype)
314
315let eval_add (v1,t1) (v2,t2) = match t1, t2 with
316  | Tpointer ty, Tint _ | Tarray (ty, _), Tint _ ->
317    let v = Value.mul (Value.of_int (sizeof ty)) v2 in
318    Value.add v1 v
319  | Tint _, Tpointer ty | Tint _, Tarray (ty, _) ->
320    let v = Value.mul (Value.of_int (sizeof ty)) v1 in
321    Value.add v2 v
322  | _ -> Value.add v1 v2
323
324let eval_sub (v1,t1) (v2,t2) = match t1, t2 with
325  | Tpointer ty, Tint _ | Tarray (ty, _), Tint _ ->
326    let v = Value.mul (Value.of_int (sizeof ty)) v2 in
327    Value.sub v1 v
328  | _ -> Value.sub v1 v2
329
330let choose_sign op_signed op_unsigned v1 v2 t =
331  let op = match t with
332    | Tint (_, Signed) -> op_signed
333    | Tint (_, Unsigned) -> op_unsigned
334    | _ -> op_unsigned in
335  op v1 v2
336
337let eval_binop ret_ctype ((_, t1) as e1) ((_, t2) as e2) op =
338  let v1 = to_int32 e1 in
339  let v2 = to_int32 e2 in
340  let e1 = (v1, t1) in
341  let e2 = (v2, t2) in
342  let v = match op with
343    | Oadd -> eval_add e1 e2
344    | Osub -> eval_sub e1 e2
345    | Omul -> Value.mul v1 v2
346    | Odiv -> choose_sign Value.div Value.divu v1 v2 t1
347    | Omod -> choose_sign Value.modulo Value.modulou v1 v2 t1
348    | Oand -> Value.and_op v1 v2
349    | Oor -> Value.or_op v1 v2
350    | Oxor -> Value.xor v1 v2
351    | Oshl-> Value.shl v1 v2
352    | Oshr-> Value.shr v1 v2
353    | Oeq -> choose_sign Value.cmp_eq Value.cmp_eq_u v1 v2 t1
354    | One -> choose_sign Value.cmp_ne Value.cmp_ne_u v1 v2 t1
355    | Olt -> choose_sign Value.cmp_lt Value.cmp_lt_u v1 v2 t1
356    | Ole -> choose_sign Value.cmp_le Value.cmp_le_u v1 v2 t1
357    | Ogt -> choose_sign Value.cmp_gt Value.cmp_gt_u v1 v2 t1
358    | Oge -> choose_sign Value.cmp_ge Value.cmp_ge_u v1 v2 t1 in
359  eval_cast (v, t1, ret_ctype)
360
361let rec get_offset_struct v size id fields =
362  let offsets = fst (Mem.concrete_offsets_size size) in
363  let fields = List.combine (List.map fst fields) offsets in
364  let off = Value.of_int (List.assoc id fields) in
365  Value.add v off
366
367let get_offset v id = function
368  | Tstruct (_, fields) as t ->
369    let size = ClightToCminor.sizeof_ctype t in
370    get_offset_struct v size id fields
371  | Tunion _ -> v
372  | _ -> assert false (* do not use on these arguments *)
373
374let is_true (v, _) = Value.is_true v
375let is_false (v, _) = Value.is_false v
376
377let rec eval_expr localenv m c (Expr (ee, tt)) =
378  match ee with
379    | Econst_int i ->
380      let v = eval_cast (Value.of_int i, Tint(I32, Signed), tt) in
381      ((v, tt),[]) 
382    | Econst_float _ -> error_float ()
383    | Evar id when is_function_type tt || is_big_type tt ->
384      let v = value_of_address (find_symbol localenv m id) in
385      ((v, tt), [])
386    | Evar id ->
387      let addr = find_symbol localenv m id in
388      let v = Mem.load m (size_of_ctype tt) addr in
389      ((v, tt), [])
390    | Ederef e when is_function_type tt || is_big_type tt ->
391      let ((v1,_),l1) = eval_expr localenv m c e in
392      ((v1,tt),l1) 
393    | Ederef e ->
394      let ((v1,_),l1) = eval_expr localenv m c e in
395      let addr = address_of_value v1 in
396      let v = Mem.load m (size_of_ctype tt) addr in
397      ((v,tt),l1) 
398    | Eaddrof exp ->
399      let ((addr,_),l) = eval_lvalue localenv m c exp in
400      ((value_of_address addr,tt),l)
401    | Ebinop (op,exp1,exp2) -> 
402      let (v1,l1) = eval_expr localenv m c exp1 in
403      let (v2,l2) = eval_expr localenv m c exp2 in
404      ((eval_binop tt v1 v2 op,tt),l1@l2)
405    | Eunop (op,exp) -> 
406      let (e1,l1) = eval_expr localenv m c exp in
407      ((eval_unop tt e1 op,tt),l1)
408    | Econdition (e1,e2,e3) ->
409      let (v1,l1) = eval_expr localenv m c e1 in
410      if is_true v1 then let (v2,l2) = eval_expr localenv m c e2 in (v2,l1@l2)
411      else
412        if is_false v1 then let (v3,l3) = eval_expr localenv m c e3 in (v3,l1@l3)
413      else (v1,l1)
414    | Eandbool (e1,e2) -> 
415      let (v1,l1) = eval_expr localenv m c e1 in
416      if is_true v1 then let (v2,l2) = eval_expr localenv m c e2 in (v2,l1@l2)
417      else (v1,l1)
418    | Eorbool (e1,e2) ->
419      let (v1,l1) = eval_expr localenv m c e1 in
420      if is_false v1 then let (v2,l2) = eval_expr localenv m c e2 in (v2,l1@l2)
421      else (v1,l1)
422    | Esizeof cty -> ((Value.of_int (sizeof cty),tt),[])
423    | Efield (e1,id) -> 
424      let ((v1,t1),l1) = eval_expr localenv m c e1 in
425      let addr = address_of_value (get_offset v1 id t1) in
426      ((Mem.load m (size_of_ctype tt) addr, tt), l1)
427    | Ecost (lbl,e1) ->
428                        (* applying current indexing on label *)
429                        let lbl = CostLabel.apply_const_indexing c lbl in
430      let (v1,l1) = eval_expr localenv m c e1 in
431      (v1,lbl::l1)
432    | Ecall _ -> assert false (* only used by the annotation process *)
433    | Ecast (cty,exp) -> 
434      let ((v,ty),l1) = eval_expr localenv m c exp in
435      ((eval_cast (v,ty,cty),tt),l1)
436
437and eval_lvalue localenv m c (Expr (e,t)) = match e with
438  | Econst_int _ | Econst_float _ | Eaddrof _ | Eunop (_,_) | Ebinop (_,_,_) 
439  | Ecast (_,_) | Econdition (_,_,_) | Eandbool (_,_)  | Eorbool (_,_) 
440  | Esizeof _ -> assert false (*Not allowed in left side of assignement*)
441  | Evar id -> ((find_symbol localenv m id,t),[])
442  | Ederef ee ->
443    let ((v,_),l1) = eval_expr localenv m c ee in 
444    ((address_of_value v,t),l1)
445  | Efield (ee,id) ->
446    let ((v,tt),l1) = eval_expr localenv m c ee in 
447    let v' = get_offset v id tt in
448    ((address_of_value v', t), l1)
449  | Ecost (lbl,ee) ->
450    let (v,l) = eval_lvalue localenv m c ee in
451    (v,lbl::l)
452  | Ecall _ -> assert false (* only used in the annotation process *)
453
454let eval_exprlist lenv mem c es =
455  let f (vs, cost_lbls) e =
456    let ((v, _), cost_lbls') = eval_expr lenv mem c e in
457    (vs @ [v], cost_lbls @ cost_lbls') in
458  List.fold_left f ([], []) es
459
460
461let bind (mem, lenv) (x, ty) v =
462  let (mem, addr) = Mem.alloc mem (sizeof ty) in
463  let mem = Mem.store mem (sizeof ty) addr v in
464  let lenv = LocalEnv.add x addr lenv in
465  (mem, lenv)
466
467let bind_var (mem, lenv) (x, ty) = bind (mem, lenv) (x, ty) Value.undef
468
469let init_fun_env mem params args vars =
470  let lenv = LocalEnv.empty in
471  let (mem, lenv) =
472    try List.fold_left2 bind (mem, lenv) params args
473    with Invalid_argument _ -> error "wrong size of arguments." in
474  List.fold_left bind_var (mem, lenv) vars
475
476let assign m v ty ptr = Mem.store m (size_of_ctype ty) ptr v
477
478
479let free_local_env mem lenv =
480  let f _ addr mem = Mem.free mem addr in
481  LocalEnv.fold f lenv mem
482
483let condition v a_true a_false =
484  if Value.is_false v then a_false
485  else if Value.is_true v then a_true
486  else error "undefined condition guard value."
487
488let eval_stmt f k e m s c =
489        match s, k with
490  | Sskip, Kseq(s,k) -> (State(f,s,k,e,m,c),[])
491  | Sskip, Kwhile(i,a,s,k') | Scontinue, Kwhile(i,a,s,k')
492  | Sskip, Kdowhile(i,a,s,k') | Scontinue, Kdowhile (i,a,s,k') ->
493                (* possibly continuing a loop *)
494                CostLabel.continue_loop i c; (* if loop is not continued, this change
495                                                will have no effect in the following. *) 
496    let ((v1,_),l1) = eval_expr e m c a in 
497    let a_false = (State(f,Sskip,k',e,m,c),l1) in
498    let a_true = (State(f,s,k,e,m,c),l1) in
499    condition v1 a_true a_false
500  | Sskip, Kfor3(i,a2,a3,s,k) | Scontinue, Kfor3(i,a2,a3,s,k) ->
501    CostLabel.continue_loop i c;
502    let ((v1,_),l1) = eval_expr e m c a2 in 
503    let a_false = (State(f,Sskip,k,e,m,c),l1) in
504    let a_true = (State(f,s,Kfor2(i,a2,a3,s,k),e,m,c),l1) in
505    condition v1 a_true a_false
506  | Sskip, Kfor2(i,a2,a3,s,k) -> (State(f,a3,Kfor3(i,a2,a3,s,k),e,m,c),[])
507  | Sskip, Kswitch k -> (State(f,Sskip,k,e,m,c),[])
508  | Sskip, Kcall _ -> 
509    let m' = free_local_env m e in
510    (Returnstate(Value.undef,k,m'),[])
511  | Sassign(a1, a2), _ -> 
512    let ((v1,t1),l1) = (eval_lvalue e m c a1) in
513    let ((v2,t2),l2) = eval_expr e m c a2 in
514    (State(f,Sskip,k,e,assign m v2 t1 v1,c),l1@l2)
515  | Scall(None,a,al), _ ->
516    let ((v1,_),l1) = eval_expr e m c a in 
517    let fd = Mem.find_fun_def m (address_of_value v1) in
518    let (vargs,l2) = eval_exprlist e m c al in
519    (Callstate(fd,vargs,Kcall(None,f,e,c,k),m),l1@l2)
520  | Scall(Some lhs,a,al), _ ->
521    let ((v1,_),l1) = eval_expr e m c a in 
522    let fd = Mem.find_fun_def m (address_of_value v1) in
523    let (vargs,l2) = eval_exprlist e m c al in
524    let (vt3,l3) = eval_lvalue e m c lhs in
525    (Callstate(fd,vargs,Kcall(Some vt3,f,e,c,k),m),l1@l2@l3)
526  | Ssequence(s1,s2), _ -> (State(f,s1,Kseq(s2,k),e,m,c),[])
527  | Sifthenelse(a,s1,s2), _ -> 
528    let ((v1,_),l1) = eval_expr e m c a in 
529    let a_true = (State(f,s1,k,e,m,c),l1) in
530    let a_false = (State(f,s2,k,e,m,c),l1) in
531    condition v1 a_true a_false
532  | Swhile(i,a,s), _ ->
533                CostLabel.enter_loop i c;
534    let ((v1,_),l1) = eval_expr e m c a in 
535    let a_false = (State(f,Sskip,k,e,m,c),l1) in
536    let a_true = (State(f,s,Kwhile(i,a,s,k),e,m,c),l1) in
537    condition v1 a_true a_false
538  | Sdowhile(i,a,s), _ ->
539                CostLabel.enter_loop i c;
540                (State(f,s,Kdowhile(i,a,s,k),e,m,c),[])
541  | Sfor(i,Sskip,a2,a3,s), _ ->
542                CostLabel.enter_loop i c;
543    let ((v1,_),l1) = eval_expr e m c a2 in 
544    let a_false = (State(f,Sskip,k,e,m,c),l1) in
545    let a_true = (State(f,s,Kfor2(i,a2,a3,s,k),e,m,c),l1) in
546    condition v1 a_true a_false
547  | Sfor(i,a1,a2,a3,s), _ -> (State(f,a1,Kseq(Sfor(i,Sskip,a2,a3,s),k),e,m,c),[])
548  | Sbreak, Kseq(s,k) -> (State(f,Sbreak,k,e,m,c),[])
549  | Sbreak, Kwhile(_,_,_,k) | Sbreak, Kdowhile(_,_,_,k)
550        | Sbreak, Kfor2(_,_,_,_,k) | Sbreak, Kswitch k -> (State(f,Sskip,k,e,m,c),[])
551  | Scontinue, Kseq(_,k)
552        | Scontinue, Kswitch k -> (State(f,Scontinue,k,e,m,c),[])
553  | Sreturn None, _ -> 
554    let m' = free_local_env m e in
555    (Returnstate(Value.undef,(call_cont k),m'),[])
556  | Sreturn (Some a), _ -> 
557    let ((v1,_),l1) = eval_expr e m c a  in
558    let m' = free_local_env m e in
559    (Returnstate(v1,call_cont k,m'),l1)
560  | Sswitch(a,sl), _ -> 
561    let ((v,_),l) = eval_expr e m c a in
562    let n = Value.to_int v in
563    (State(f,(seq_of_labeled_statement (select_switch n sl)),Kswitch k,e,m,c),l)
564  | Slabel(lbl,s), _ -> (State(f,s,k,e,m,c),[])
565  | Scost(lbl,s), _ ->
566                (* applying current indexing on label *)
567                let lbl = CostLabel.apply_const_indexing c lbl in
568                (State(f,s,k,e,m,c),[lbl])
569  | Sgoto lbl, _ ->
570                (* if we exit an indexed loop, we don't care. It should not be possible to*)
571                (* enter an indexed loop that is not the current one, so we do nothing*)
572                (* to loop indexes *)
573    let (s', k') = find_label lbl f.fn_body (call_cont k) in
574    (State(f,s',k',e,m,c),[])
575  | _ -> assert false (* should be impossible *)
576
577
578module InterpretExternal = Primitive.Interpret (Mem)
579
580let interpret_external k mem f args =
581  let (mem', v) = match InterpretExternal.t mem f args with
582    | (mem', InterpretExternal.V vs) ->
583      let v = if List.length vs = 0 then Value.undef else List.hd vs in
584      (mem', v)
585    | (mem', InterpretExternal.A addr) -> (mem', value_of_address addr) in
586  Returnstate (v, k, mem')
587
588let step_call args cont mem = function
589  | Internal f -> 
590    let (mem', e) = init_fun_env mem f.fn_params args f.fn_vars in
591                (* initializing loop indices *)
592                let max_depth = ClightUtils.max_loop_index_lbld f.fn_body in
593                let c = Array.make max_depth 0 in
594    State (f, f.fn_body, cont, e, mem', c)
595  | External(id,targs,tres) when List.length targs = List.length args -> 
596    interpret_external cont mem id args
597  | External(id,_,_) -> 
598    error ("wrong size of arguments when calling external " ^ id ^ ".")
599
600let step = function
601  | State(f,stmt,k,e,m,c) -> eval_stmt f k e m stmt c
602  | Callstate(fun_def,vargs,k,m) -> (step_call vargs k m fun_def,[])
603  | Returnstate(v,Kcall(None,f,e,c,k),m) -> (State(f,Sskip,k,e,m,c),[])
604  | Returnstate(v,Kcall((Some(vv, ty)),f,e,c,k),m) -> 
605    let m' = assign m v ty vv in
606    (State(f,Sskip,k,e,m',c),[])
607  | _ -> error "state malformation."
608
609
610let data_of_init_data = function
611  | Init_int8 i         -> Data_int8 i
612  | Init_int16 i        -> Data_int16 i
613  | Init_int32 i        -> Data_int32 i
614  | Init_float32 f      -> error_float ()
615  | Init_float64 f      -> error_float ()
616  | Init_space i        -> error "bad global initialization style."
617  | Init_addrof (x,off) -> assert false (* TODO: need the size of [x]'s cells *)
618
619let datas_of_init_datas = function
620  | [Init_space _] -> None
621  | l -> Some (List.map data_of_init_data l)
622
623let init_mem prog =
624  let f_var mem ((x, init_datas), ty) =
625    Mem.add_var mem x (ClightToCminor.sizeof_ctype ty)
626      (datas_of_init_datas init_datas) in
627  let mem = List.fold_left f_var Mem.empty prog.prog_vars in
628  let f_fun_def mem (f, def) = Mem.add_fun_def mem f def in
629  List.fold_left f_fun_def mem prog.prog_funct
630
631let compute_result v =
632  if Value.is_int v then IntValue.Int32.cast (Value.to_int_repr v)
633  else IntValue.Int32.zero
634
635let rec exec debug trace (state, l) =
636  let cost_labels = l @ trace in
637  let print_and_return_result res =
638    if debug then Printf.printf "Result = %s\n%!"
639      (IntValue.Int32.to_string res) ;
640    (res, cost_labels) in
641  if debug then print_state state ;
642  match state with
643    | Returnstate(v,Kstop,_) -> (* Explicit return in main *)
644      print_and_return_result (compute_result v)
645    | State(_,Sskip,Kstop,_,_,_) -> (* Implicit return in main *)
646      print_and_return_result IntValue.Int32.zero
647    | state -> exec debug cost_labels (step state)
648
649let interpret debug prog =
650  Printf.printf "*** Clight interpret ***\n%!" ;
651  match prog.prog_main with
652    | None -> (IntValue.Int32.zero, [])
653    | Some main ->
654      let mem = init_mem prog in
655      let first_state = (Callstate (find_fundef main mem,[],Kstop,mem),[]) in
656      exec debug [] first_state
Note: See TracBrowser for help on using the repository browser.