source: C-semantics/IOMonad.ma @ 366

include "Plogic/russell_support.ma".
include "extralib.ma".
include "Errors.ma".

(* IO monad *)

ninductive IO (output:Type) (input:output → Type) (T:Type) : Type ≝
| Interact : ∀o:output. (input o → IO output input T) → IO output input T
| Value : T → IO output input T
| Wrong : IO output input T.

nlet rec bindIO (O:Type) (I:O → Type) (T,T':Type) (v:IO O I T) (f:T → IO O I T') on v : IO O I T' ≝
match v with
[ Interact out k ⇒ (Interact ??? out (λres. bindIO O I T T' (k res) f))
| Value v' ⇒ (f v')
| Wrong ⇒ Wrong O I T'
].

nlet rec bindIO2 (O:Type) (I:O → Type) (T1,T2,T':Type) (v:IO O I (T1×T2)) (f:T1 → T2 → IO O I T') on v : IO O I T' ≝
match v with
[ Interact out k ⇒ (Interact ??? out (λres. bindIO2 ?? T1 T2 T' (k res) f))
| Value v' ⇒ match v' with [ mk_pair v1 v2 ⇒ f v1 v2 ]
| Wrong ⇒ Wrong ?? T'
].

ndefinition err_to_io : ∀O,I,T. res T → IO O I T ≝
λO,I,T,v. match v with [ OK v' ⇒ Value O I T v' | Error ⇒ Wrong O I T ].
ncoercion err_to_io : ∀O,I,A.∀c:res A.IO O I A ≝ err_to_io on _c:res ? to IO ???.
ndefinition err_to_io_sig : ∀O,I,T.∀P:T → Prop. res (sigma T P) → IO O I (sigma T P) ≝
λO,I,T,P,v. match v with [ OK v' ⇒ Value O I (sigma T P) v' | Error ⇒ Wrong O I (sigma T P) ].
(*ncoercion err_to_io_sig : ∀O,I,A.∀P:A → Prop.∀c:res (sigma A P).IO O I (sigma A P) ≝ err_to_io_sig on _c:res (sigma ??) to IO ?? (sigma ??).*)


(* If the original definitions are vague enough, do I need to do this? *)
notation > "! ident v ← e; e'" with precedence 40 for @{'bindIO ${e} (λ${ident v}.${e'})}.
notation > "! ident v : ty ← e; e'" with precedence 40 for @{'bindIO ${e} (λ${ident v} : ${ty}.${e'})}.
notation < "vbox(! \nbsp ident v ← e; break e')" with precedence 40 for @{'bindIO ${e} (λ${ident v}.${e'})}.
notation < "vbox(! \nbsp ident v : ty ← e; break e')" with precedence 40 for @{'bindIO ${e} (λ${ident v} : ${ty}.${e'})}.
notation > "! 〈ident v1, ident v2〉 ← e; e'" with precedence 40 for @{'bindIO2 ${e} (λ${ident v1}.λ${ident v2}.${e'})}.
notation > "! 〈ident v1 : ty1, ident v2 : ty2〉 ← e; e'" with precedence 40 for @{'bindIO2 ${e} (λ${ident v1} : ${ty1}.λ${ident v2} : ${ty2}.${e'})}.
notation < "vbox(! \nbsp 〈ident v1, ident v2〉 ← e; break e')" with precedence 40 for @{'bindIO2 ${e} (λ${ident v1}.λ${ident v2}.${e'})}.
notation < "vbox(! \nbsp 〈ident v1 : ty1, ident v2 : ty2〉 ← e; break e')" with precedence 40 for @{'bindIO2 ${e} (λ${ident v1} : ${ty1}.λ${ident v2} : ${ty2}.${e'})}.
interpretation "IO monad bind" 'bindIO e f = (bindIO ???? e f).
interpretation "IO monad pair bind" 'bindIO2 e f = (bindIO2 ????? e f).
(**)
nlet rec P_io O I (A:Type) (P:A → Prop) (v:IO O I A) on v : Prop ≝
match v return λ_.Prop with
[ Wrong ⇒ True
| Value z ⇒ P z
| Interact out k ⇒ ∀v'.P_io O I A P (k v')
].

nlet rec P_io' O I (A:Type) (P:A → Prop) (v:IO O I A) on v : Prop ≝
match v return λ_.Prop with
[ Wrong ⇒ False
| Value z ⇒ P z
| Interact out k ⇒ ∀v'.P_io' O I A P (k v')
].

ndefinition P_to_P_option_io : ∀O,I,A.∀P:A → Prop.option (IO O I A) → Prop ≝
  λO,I,A,P,a.match a with
   [ None ⇒ False
   | Some y ⇒ P_io O I A P y
   ].

nlet rec io_inject_0 O I (A:Type) (P:A → Prop) (a:IO O I A) (p:P_io O I A P a) on a : IO O I (sigma A P) ≝
(match a return λa'.P_io O I A P a' → ? with
 [ Wrong ⇒ λ_. Wrong O I ?
 | Value c ⇒ λp'. Value ??? (sig_intro A P c p')
 | Interact out k ⇒ λp'. Interact ??? out (λv. io_inject_0 O I A P (k v) (p' v))
 ]) p.

ndefinition io_inject : ∀O,I,A.∀P:A → Prop.∀a:option (IO O I A).∀p:P_to_P_option_io O I A P a.IO O I (sigma A P) ≝ 
  λO,I,A.λP:A → Prop.λa:option (IO O I A).λp:P_to_P_option_io O I A P a. 
  (match a return λa'.P_to_P_option_io O I A P a' → IO O I (sigma A P) with
   [ None ⇒ λp'.?
   | Some b ⇒ λp'. io_inject_0 O I A P b p'
   ]) p.
nelim p'; nqed.

nlet rec io_eject O I (A:Type) (P: A → Prop) (a:IO O I (sigma A P)) on a : IO O I A ≝ 
match a with
[ Wrong ⇒ Wrong ???
| Value b ⇒ match b with [ sig_intro w p ⇒ Value ??? w]
| Interact out k ⇒ Interact ??? out (λv. io_eject ?? A P (k v))
].

ncoercion io_inject : 
  ∀O,I,A.∀P:A → Prop.∀a.∀p:P_to_P_option_io O I ? P a.IO O I (sigma A P) ≝ io_inject 
  on a:option (IO ???) to IO ?? (sigma ? ?).
ncoercion io_eject : ∀O,I,A.∀P:A → Prop.∀c:IO O I (sigma A P).IO O I A ≝ io_eject 
  on _c:IO ?? (sigma ? ?) to IO ???.

ndefinition opt_to_io : ∀O,I,T.option T → IO O I T ≝
λO,I,T,v. match v with [ None ⇒ Wrong ?? T | Some v' ⇒ Value ??? v' ].
ncoercion opt_to_io : ∀O,I,T.∀v:option T. IO O I T ≝ opt_to_io on _v:option ? to IO ???.

nlemma sig_bindIO_OK: ∀O,I,A,B. ∀P:A → Prop. ∀P':B → Prop. ∀e:IO O I (sigma A P). ∀f:sigma A P → IO O I B.
  (∀v:A. ∀p:P v. P_io O I ? P' (f (sig_intro A P v p))) →
  P_io O I ? P' (bindIO O I (sigma A P) B e f).
#O I A B P P' e f; nelim e;
##[ #out k IH; #IH'; nwhd; #res; napply IH; //;
##| #v0; nelim v0; #v Hv IH; nwhd; napply IH;
##| //;
##] nqed.

nlemma sig_bindIO2_OK: ∀O,I,A,B,C. ∀P:(A×B) → Prop. ∀P':C → Prop. ∀e:IO O I (sigma (A×B) P). ∀f: A → B → IO O I C.
  (∀vA:A.∀vB:B. ∀p:P 〈vA,vB〉. P_io O I ? P' (f vA vB)) →
  P_io O I ? P' (bindIO2 O I A B C e f).
#I O A B C P P' e f; nelim e;
##[ #out k IH; #IH'; nwhd; #res; napply IH; napply IH';
##| #v0; nelim v0; #v; nelim v; #vA vB Hv IH; napply IH; //;
##| //;
##] nqed.

nlemma opt_bindIO_OK: ∀O,I,A,B. ∀P:B → Prop. ∀e:option A. ∀f: A → IO O I B.
  (∀v:A. e = Some A v → P_io O I ? P (f v)) →
  P_io O I ? P (bindIO O I A B e f).
#I O A B P e; nelim e; //; #v f H; napply H; //;
nqed.

nlemma opt_bindIO2_OK: ∀O,I,A,B,C. ∀P:C → Prop. ∀e:option (A×B). ∀f: A → B → IO O I C.
  (∀vA:A.∀vB:B. e = Some (A×B) 〈vA,vB〉 → P_io O I ? P (f vA vB)) →
  P_io O I ? P (bindIO2 O I A B C e f).
#I O A B C P e; nelim e; //; #v; ncases v; #vA vB f H; napply H; //;
nqed.

nlemma res_bindIO_OK: ∀O,I,A,B. ∀P:B → Prop. ∀e:res A. ∀f: A → IO O I B.
  (∀v:A. e = OK A v → P_io O I ? P (f v)) →
  P_io O I ? P (bindIO O I A B e f).
#I O A B P e; nelim e; //; #v f H; napply H; //;
nqed.

nlemma res_bindIO2_OK: ∀O,I,A,B,C. ∀P:C → Prop. ∀e:res (A×B). ∀f: A → B → IO O I C.
  (∀vA:A.∀vB:B. e = OK (A×B) 〈vA,vB〉 → P_io O I ? P (f vA vB)) →
  P_io O I ? P (bindIO2 O I A B C e f).
#I O A B C P e; nelim e; //; #v; ncases v; #vA vB f H; napply H; //;
nqed.

nlemma bindIO_OK: ∀O,I,A,B. ∀P:B → Prop. ∀e:IO O I A. ∀f: A → IO O I B.
  (∀v:A. P_io O I ? P (f v)) →
  P_io O I ? P (bindIO O I A B e f).
#I O A B P e; nelim e;
##[ #out k IH; #f H; nwhd; #res; napply IH; //;
##| #v f H; napply H;
##| //;
##] nqed.

nlemma bindIO2_OK: ∀O,I,A,B,C. ∀P:C → Prop. ∀e:IO O I (A×B). ∀f: A → B → IO O I C.
  (∀v1:A.∀v2:B. P_io O I ? P (f v1 v2)) →
  P_io O I ? P (bindIO2 O I A B C e f).
#I O A B C P e; nelim e;
##[ #out k IH; #f H; nwhd; #res; napply IH; //;
##| #v; ncases v; #v1 v2 f H; napply H;
##| //;
##] nqed.

nlemma P_bindIO_OK: ∀O,I,A,B. ∀P':A → Prop. ∀P:B → Prop. ∀e:IO O I A. ∀f: A → IO O I B.
  P_io … P' e →
  (∀v:A. P' v → P_io O I ? P (f v)) →
  P_io O I ? P (bindIO O I A B e f).
#I O A B P' P e; nelim e;
##[ #out k IH f He H; nwhd in He ⊢ %; #res; napply IH; /2/;
##| #v f He H; napply H; napply He;
##| //;
##] nqed.

nlemma P_bindIO2_OK: ∀O,I,A,B,C. ∀P':A×B → Prop. ∀P:C → Prop. ∀e:IO O I (A×B). ∀f: A → B → IO O I C.
  P_io … P' e →
  (∀v1:A.∀v2:B. P' 〈v1,v2〉 → P_io O I ? P (f v1 v2)) →
  P_io O I ? P (bindIO2 O I A B C e f).
#I O A B C P' P e; nelim e;
##[ #out k IH f He H; nwhd in He ⊢ %; #res; napply IH; /2/;
##| #v; ncases v; #v1 v2 f He H; napply H; napply He;
##| //;
##] nqed.


(* TODO: is there a way to prove this without extensionality?

nlemma bind_assoc_r: ∀A,B,C,e,f,g.
  bindIO B C (bindIO A B e f) g = bindIO A C e (λx.bindIO B C (f x) g).
#A B C e f g; nelim e;
##[ #fn args k IH; nwhd in ⊢ (???%);
nnormalize; 
*)

nlemma extract_subset_pair_io: ∀O,I,A,B,C,P. ∀e:{e:A×B | P e}. ∀Q:A→B→IO O I C. ∀R:C→Prop.
  (∀a,b. eject ?? e = 〈a,b〉 → P 〈a,b〉 → P_io O I ? R (Q a b)) →
  P_io O I ? R (match eject ?? e with [ mk_pair a b ⇒ Q a b ]).
#I O A B C P e Q R; ncases e; #e'; ncases e'; nnormalize;
##[ *;
##| #e''; ncases e''; #a b Pab H; nnormalize; /2/;
##] nqed.