source: C-semantics/IOMonad.ma @ 125

Last change on this file since 125 was 125, checked in by campbell, 9 years ago

Unify memory space / pointer types.
Implement global variable initialisation and lookup.
Global variables get memory spaces, local variables could be anywhere (for now).

File size: 6.1 KB
Line 
1include "Plogic/russell_support.ma".
2include "extralib.ma".
3include "Errors.ma".
4
5(* IO monad *)
6
7ninductive IO (input,output:Type) (T:Type) : Type ≝
8| Interact : output → (input → IO input output T) → IO input output T
9| Value : T → IO input output T
10| Wrong : IO input output T.
11
12nlet rec bindIO (I,O,T,T':Type) (v:IO I O T) (f:T → IO I O T') on v : IO I O T' ≝
13match v with
14[ Interact out k ⇒ (Interact ??? out (λres. bindIO I O T T' (k res) f))
15| Value v' ⇒ (f v')
16| Wrong ⇒ Wrong I O T'
17].
18
19nlet rec bindIO2 (I,O,T1,T2,T':Type) (v:IO I O (T1×T2)) (f:T1 → T2 → IO I O T') on v : IO I O T' ≝
20match v with
21[ Interact out k ⇒ (Interact ??? out (λres. bindIO2 ?? T1 T2 T' (k res) f))
22| Value v' ⇒ match v' with [ mk_pair v1 v2 ⇒ f v1 v2 ]
23| Wrong ⇒ Wrong ?? T'
24].
25
26ndefinition err_to_io : ∀I,O,T. res T → IO I O T ≝
27λI,O,T,v. match v with [ OK v' ⇒ Value I O T v' | Error ⇒ Wrong I O T ].
28(*ncoercion err_to_io : ∀I,O,A.∀c:res A.IO I O A ≝ err_to_io on _c:res ? to IO ???.*)
29ndefinition err_to_io_sig : ∀I,O,T.∀P:T → Prop. res (sigma T P) → IO I O (sigma T P) ≝
30λI,O,T,P,v. match v with [ OK v' ⇒ Value I O (sigma T P) v' | Error ⇒ Wrong I O (sigma T P) ].
31ncoercion err_to_io_sig : ∀I,O,A.∀P:A → Prop.∀c:res (sigma A P).IO I O (sigma A P) ≝ err_to_io_sig on _c:res (sigma ??) to IO ?? (sigma ??).
32
33
34(* If the original definitions are vague enough, do I need to do this? *)
35notation "! ident v ← e;: e'" right associative with precedence 40 for @{'bindIO ${e} (λ${ident v}.${e'})}.
36notation "! 〈ident v1, ident v2〉 ← e;: e'" right associative with precedence 40 for @{'bindIO2 ${e} (λ${ident v1}.λ${ident v2}.${e'})}.
37interpretation "IO monad bind" 'bindIO e f = (bindIO ???? e f).
38interpretation "IO monad pair bind" 'bindIO2 e f = (bindIO2 ????? e f).
39(**)
40nlet rec P_io (I,O,A:Type) (P:A → Prop) (v:IO I O A) on v : Prop ≝
41match v return λ_.Prop with
42[ Wrong ⇒ True
43| Value z ⇒ P z
44| Interact out k ⇒ ∀v'.P_io I O A P (k v')
45].
46
47nlet rec P_io' (I,O,A:Type) (P:A → Prop) (v:IO I O A) on v : Prop ≝
48match v return λ_.Prop with
49[ Wrong ⇒ False
50| Value z ⇒ P z
51| Interact out k ⇒ ∀v'.P_io' I O A P (k v')
52].
53
54ndefinition P_to_P_option_io : ∀I,O,A.∀P:A → Prop.option (IO I O A) → Prop ≝
55  λI,O,A,P,a.match a with
56   [ None ⇒ False
57   | Some y ⇒ P_io I O A P y
58   ].
59
60nlet rec io_inject_0 (I,O,A:Type) (P:A → Prop) (a:IO I O A) (p:P_io I O A P a) on a : IO I O (sigma A P) ≝
61(match a return λa'.a=a' → ? with
62 [ Wrong ⇒ λ_. Wrong I O ?
63 | Value c ⇒ λe2. Value ??? (sig_intro A P c ?)
64 | Interact out k ⇒ λe2. Interact ??? out (λv. io_inject_0 I O A P (k v) ?)
65 ]) (refl ? a).
66nrewrite > e2 in p; nwhd in ⊢ (% → ?); //;
67nqed.
68
69ndefinition io_inject : ∀I,O,A.∀P:A → Prop.∀a:option (IO I O A).∀p:P_to_P_option_io I O A P a.IO I O (sigma A P) ≝
70  λI,O,A.λP:A → Prop.λa:option (IO I O A).λp:P_to_P_option_io I O A P a.
71  (match a return λa'.a=a' → IO I O (sigma A P) with
72   [ None ⇒ λe1.?
73   | Some b ⇒ λe1. io_inject_0 I O A P b ?
74   ]) (refl ? a).
75##[ nrewrite > e1 in p; nnormalize; *;
76##| nrewrite > e1 in p; nnormalize; //
77##] nqed.
78
79nlet rec io_eject (I,O,A:Type) (P: A → Prop) (a:IO I O (sigma A P)) on a : IO I O A ≝
80match a with
81[ Wrong ⇒ Wrong ???
82| Value b ⇒ match b with [ sig_intro w p ⇒ Value ??? w]
83| Interact out k ⇒ Interact ??? out (λv. io_eject ?? A P (k v))
84].
85
86ncoercion io_inject :
87  ∀I,O,A.∀P:A → Prop.∀a.∀p:P_to_P_option_io I O ? P a.IO I O (sigma A P) ≝ io_inject
88  on a:option (IO ???) to IO ?? (sigma ? ?).
89ncoercion io_eject : ∀I,O,A.∀P:A → Prop.∀c:IO I O (sigma A P).IO I O A ≝ io_eject
90  on _c:IO ?? (sigma ? ?) to IO ???.
91
92ndefinition opt_to_io : ∀I,O,T.option T → IO I O T ≝
93λI,O,T,v. match v with [ None ⇒ Wrong I O T | Some v' ⇒ Value I O T v' ].
94ncoercion opt_to_io : ∀I,O,T.∀v:option T. IO I O T ≝ opt_to_io on _v:option ? to IO ???.
95
96nlemma sig_bindIO_OK: ∀I,O,A,B. ∀P:A → Prop. ∀P':B → Prop. ∀e:IO I O (sigma A P). ∀f:sigma A P → IO I O B.
97  (∀v:A. ∀p:P v. P_io I O ? P' (f (sig_intro A P v p))) →
98  P_io I O ? P' (bindIO I O (sigma A P) B e f).
99#I O A B P P' e f; nelim e;
100##[ #out k IH; #IH'; nwhd; #res; napply IH; //;
101##| #v0; nelim v0; #v Hv IH; nwhd; napply IH;
102##| //;
103##] nqed.
104
105nlemma sig_bindIO2_OK: ∀I,O,A,B,C. ∀P:(A×B) → Prop. ∀P':C → Prop. ∀e:IO I O (sigma (A×B) P). ∀f: A → B → IO I O C.
106  (∀vA:A.∀vB:B. ∀p:P 〈vA,vB〉. P_io I O ? P' (f vA vB)) →
107  P_io I O ? P' (bindIO2 I O A B C e f).
108#I O A B C P P' e f; nelim e;
109##[ #out k IH; #IH'; nwhd; #res; napply IH; napply IH';
110##| #v0; nelim v0; #v; nelim v; #vA vB Hv IH; napply IH; //;
111##| //;
112##] nqed.
113
114nlemma opt_bindIO_OK: ∀I,O,A,B. ∀P:B → Prop. ∀e:option A. ∀f: A → IO I O B.
115  (∀v:A. e = Some A v → P_io I O ? P (f v)) →
116  P_io I O ? P (bindIO I O A B e f).
117#I O A B P e; nelim e; //; #v f H; napply H; //;
118nqed.
119
120nlemma opt_bindIO2_OK: ∀I,O,A,B,C. ∀P:C → Prop. ∀e:option (A×B). ∀f: A → B → IO I O C.
121  (∀vA:A.∀vB:B. e = Some (A×B) 〈vA,vB〉 → P_io I O ? P (f vA vB)) →
122  P_io I O ? P (bindIO2 I O A B C e f).
123#I O A B C P e; nelim e; //; #v; ncases v; #vA vB f H; napply H; //;
124nqed.
125
126nlemma bindIO_OK: ∀I,O,A,B. ∀P:B → Prop. ∀e:IO I O A. ∀f: A → IO I O B.
127  (∀v:A. P_io I O ? P (f v)) →
128  P_io I O ? P (bindIO I O A B e f).
129#I O A B P e; nelim e;
130##[ #out k IH; #f H; nwhd; #res; napply IH; //;
131##| #v f H; napply H;
132##| //;
133##] nqed.
134
135(* TODO: is there a way to prove this without extensionality?
136
137nlemma bind_assoc_r: ∀A,B,C,e,f,g.
138  bindIO B C (bindIO A B e f) g = bindIO A C e (λx.bindIO B C (f x) g).
139#A B C e f g; nelim e;
140##[ #fn args k IH; nwhd in ⊢ (???%);
141nnormalize;
142*)
143
144nlemma extract_subset_pair_io: ∀I,O,A,B,C,P. ∀e:{e:A×B | P e}. ∀Q:A→B→IO I O C. ∀R:C→Prop.
145  (∀a,b. eject ?? e = 〈a,b〉 → P 〈a,b〉 → P_io I O ? R (Q a b)) →
146  P_io I O ? R (match eject ?? e with [ mk_pair a b ⇒ Q a b ]).
147#I O A B C P e Q R; ncases e; #e'; ncases e'; nnormalize;
148##[ *;
149##| #e''; ncases e''; #a b Pab H; nnormalize; /2/;
150##] nqed.
151
Note: See TracBrowser for help on using the repository browser.