source: C-semantics/CexecIO.ma @ 125

Last change on this file since 125 was 125, checked in by campbell, 10 years ago

Unify memory space / pointer types.
Implement global variable initialisation and lookup.
Global variables get memory spaces, local variables could be anywhere (for now).

File size: 35.6 KB
Line 
1
2include "Csem.ma".
3
4include "extralib.ma".
5include "IOMonad.ma".
6
7include "Plogic/russell_support.ma".
8
9ndefinition P_to_P_option_res : ∀A:Type[0].∀P:A → CProp[0].option (res A) → CProp[0] ≝
10  λA,P,a.match a with [ None ⇒ False | Some y ⇒ match y return λ_.CProp[0] with [ Error ⇒ True | OK z ⇒ P z ]].
11
12ndefinition err_inject : ∀A.∀P:A → Prop.∀a:option (res A).∀p:P_to_P_option_res A P a.res (sigma A P) ≝
13  λA.λP:A → Prop.λa:option (res A).λp:P_to_P_option_res A P a.
14  (match a return λa'.a=a' → res (sigma A P) with
15   [ None ⇒ λe1.?
16   | Some b ⇒ λe1.(match b return λb'.b=b' → ? with
17     [ Error ⇒ λ_. Error ?
18     | OK c ⇒ λe2. OK ? (sig_intro A P c ?)
19     ]) (refl ? b)
20   ]) (refl ? a).
21##[ nrewrite > e1 in p; nnormalize; *;
22##| nrewrite > e1 in p; nrewrite > e2; nnormalize; //
23##] nqed.
24
25ndefinition err_eject : ∀A.∀P: A → Prop. res (sigma A P) → res A ≝
26  λA,P,a.match a with [ Error ⇒ Error ? | OK b ⇒
27    match b with [ sig_intro w p ⇒ OK ? w] ].
28
29ndefinition sig_eject : ∀A.∀P: A → Prop. sigma A P → A ≝
30  λA,P,a.match a with [ sig_intro w p ⇒ w].
31
32ncoercion err_inject :
33  ∀A.∀P:A → Prop.∀a.∀p:P_to_P_option_res ? P a.res (sigma A P) ≝ err_inject
34  on a:option (res ?) to res (sigma ? ?).
35ncoercion err_eject : ∀A.∀P:A → Prop.∀c:res (sigma A P).res A ≝ err_eject
36  on _c:res (sigma ? ?) to res ?.
37ncoercion sig_eject : ∀A.∀P:A → Prop.∀c:sigma A P.A ≝ sig_eject
38  on _c:sigma ? ? to ?.
39
40ndefinition bool_of_val_3 : ∀v:val. ∀ty:type. res (Σr:bool. bool_of_val v ty (of_bool r)) ≝
41  λv,ty. match v in val with
42  [ Vint i ⇒ match ty with
43    [ Tint _ _ ⇒ Some ? (OK ? (¬eq i zero))
44    | Tpointer _ _ ⇒ Some ? (OK ? (¬eq i zero))
45    | _ ⇒ Some ? (Error ?)
46    ]
47  | Vfloat f ⇒ match ty with
48    [ Tfloat _ ⇒ Some ? (OK ? (¬Fcmp Ceq f Fzero))
49    | _ ⇒ Some ? (Error ?)
50    ]
51  | Vptr _ _ _ ⇒ match ty with
52    [ Tint _ _ ⇒ Some ? (OK ? true)
53    | Tpointer _ _ ⇒ Some ? (OK ? true)
54    | _ ⇒ Some ? (Error ?)
55    ]
56  | _ ⇒ Some ? (Error ?)
57  ]. nwhd; //;
58##[ ##1,2: nlapply (eq_spec c0 zero); nelim (eq c0 zero);
59  ##[ ##1,3: #e; nrewrite > e; napply bool_of_val_false; //;
60  ##| ##2,4: #ne; napply bool_of_val_true; /2/;
61  ##]
62##| nelim (eq_dec c0 Fzero);
63  ##[ #e; nrewrite > e; nrewrite > (Feq_zero_true …); napply bool_of_val_false; //;
64  ##| #ne; nrewrite > (Feq_zero_false …); //; napply bool_of_val_true; /2/;
65  ##]
66##| ##4,5: napply bool_of_val_true; //
67##] nqed.
68
69ndefinition err_eq ≝ λA,P. λx:res (sigma A P). λy:A.
70  match x with [ Error ⇒ False | OK x' ⇒
71    match x' with [ sig_intro x'' _ ⇒ x'' = y ]].
72(* TODO: can I write a coercion for the above? *)
73
74(* Same as before, except we have to use a slightly different "equality". *)
75
76nlemma bool_of_val_3_complete : ∀v,ty,r. bool_of_val v ty r → ∃b. r = of_bool b ∧ err_eq ?? (bool_of_val_3 v ty) b.
77#v ty r H; nelim H; #v t H'; nelim H';
78  ##[ #i is s ne; @ true; @; //; nwhd; nrewrite > (eq_false … ne); //;
79  ##| #p b i i0 s; @ true; @; //
80  ##| #i p t ne; @ true; @; //; nwhd; nrewrite > (eq_false … ne); //;
81  ##| #p b i p0 t0; @ true; @; //
82  ##| #f s ne; @ true; @; //; nwhd; nrewrite > (Feq_zero_false … ne); //;
83  ##| #i s; @ false; @; //; (*nwhd; nrewrite > (eq_true …); //;*)
84  ##| #p t; @ false; @; //; (*nwhd; nrewrite > (eq_true …); //;*)
85  ##| #s; @ false; @; //; nwhd; nrewrite > (Feq_zero_true …); //;
86  ##]
87nqed.
88
89(* Prove a few minor results to make proof obligations easy. *)
90
91nlemma bind_assoc_r: ∀A,B,C,e,f,g.
92  bind B C (bind A B e f) g = bind A C e (λx.bind B C (f x) g).
93#A B C e f g; ncases e; nnormalize; //; nqed.
94
95nlemma bind_OK: ∀A,B,P,e,f.
96  (∀v. e = OK A v → match f v with [ Error ⇒ True | OK v' ⇒ P v' ]) →
97  match bind A B e f with [ Error ⇒ True | OK v ⇒ P v ].
98#A B P e f; nelim e; /2/; nqed.
99
100nlemma sig_bind_OK: ∀A,B. ∀P:A → Prop. ∀P':B → Prop. ∀e:res (sigma A P). ∀f:sigma A P → res B.
101  (∀v:A. ∀p:P v. match f (sig_intro A P v p) with [ Error ⇒ True | OK v' ⇒ P' v'] ) →
102  match bind (sigma A P) B e f with [ Error ⇒ True | OK v' ⇒ P' v' ].
103#A B P P' e f; nelim e;
104##[ #v0; nelim v0; #v Hv IH; napply IH;
105##| #_; napply I;
106##] nqed.
107
108nlemma bind2_OK: ∀A,B,C,P,e,f.
109  (∀v1,v2. e = OK ? 〈v1,v2〉 → match f v1 v2 with [ Error ⇒ True | OK v' ⇒ P v' ]) →
110  match bind2 A B C e f with [ Error ⇒ True | OK v ⇒ P v ].
111#A B C P e f; nelim e; //; #v; ncases v; /2/; nqed.
112
113nlemma sig_bind2_OK: ∀A,B,C. ∀P:A×B → Prop. ∀P':C → Prop. ∀e:res (sigma (A×B) P). ∀f:A → B → res C.
114  (∀v1:A.∀v2:B. P 〈v1,v2〉 → match f v1 v2 with [ Error ⇒ True | OK v' ⇒ P' v'] ) →
115  match bind2 A B C e f with [ Error ⇒ True | OK v' ⇒ P' v' ].
116#A B C P P' e f; nelim e; //;
117#v0; nelim v0; #v; nelim v; #v1 v2 Hv IH; napply IH; //; nqed.
118
119nlemma reinject: ∀A. ∀P,P':A → Prop. ∀e:res (sigma A P').
120  (∀v:A. err_eq A P' e v → P' v → P v) →
121  match err_eject A P' e with [ Error ⇒ True | OK v' ⇒ P v' ].
122#A P P' e; ncases e; //;
123#v0; nelim v0; #v Pv' IH; /2/;
124nqed.
125
126nlemma bool_val_distinct: Vtrue ≠ Vfalse.
127@; #H; nwhd in H:(??%%); ndestruct; napply (absurd ? e0 one_not_zero);
128nqed.
129
130nlemma bool_of: ∀v,ty,b. bool_of_val v ty (of_bool b) →
131  if b then is_true v ty else is_false v ty.
132#v ty b; ncases b; #H; ninversion H; #v' ty' H' ev et ev; //;
133napply False_ind; napply (absurd ? ev ?);
134##[ ##2: napply sym_neq ##] napply bool_val_distinct;
135nqed.
136
137ndefinition opt_to_res ≝ λA.λv:option A. match v with [ None ⇒ Error A | Some v ⇒ OK A v ].
138nlemma opt_OK: ∀A,P,e.
139  (∀v. e = Some ? v → P v) →
140  match opt_to_res A e with [ Error ⇒ True | OK v ⇒ P v ].
141#A P e; nelim e; /2/;
142nqed.
143
144nlemma opt_bind_OK: ∀A,B,P,e,f.
145  (∀v. e = Some A v → match f v with [ Error ⇒ True | OK v' ⇒ P v' ]) →
146  match bind A B (opt_to_res A e) f with [ Error ⇒ True | OK v ⇒ P v ].
147#A B P e f; nelim e; nnormalize; /2/; nqed.
148
149nlemma extract_subset_pair: ∀A,B,C,P. ∀e:{e:A×B | P e}. ∀Q:A→B→res C. ∀R:C→Prop.
150  (∀a,b. eject ?? e = 〈a,b〉 → P 〈a,b〉 → match Q a b with [ OK v ⇒ R v | Error ⇒ True]) →
151  match match eject ?? e with [ mk_pair a b ⇒ Q a b ] with [ OK v ⇒ R v | Error ⇒ True ].
152#A B C P e Q R; ncases e; #e'; ncases e'; nnormalize;
153##[ #H; napply (False_ind … H);
154##| #e''; ncases e''; #a b Pab H; nnormalize; /2/;
155##] nqed.
156
157(*
158nremark err_later: ∀A,B. ∀e:res A. match e with [ Error ⇒ Error B | OK v ⇒ Error B ] = Error B.
159#A B e; ncases e; //; nqed.
160*)
161
162nlet rec try_cast_null (m:mem) (i:int) (ty:type) (ty':type) : res (Σv':val. cast m (Vint i) ty ty' v') ≝
163match eq i zero with
164[ true ⇒
165  match ty with
166  [ Tpointer _ _ ⇒
167    match ty' with
168    [ Tpointer _ _ ⇒ Some ? (OK ? (Vint i))
169    | Tarray _ _ _ ⇒ Some ? (OK ? (Vint i))
170    | Tfunction _ _ ⇒ Some ? (OK ? (Vint i))
171    | _ ⇒ Some ? (Error ?)
172    ]
173  | Tarray _ _ _ ⇒
174    match ty' with
175    [ Tpointer _ _ ⇒ Some ? (OK ? (Vint i))
176    | Tarray _ _ _ ⇒ Some ? (OK ? (Vint i))
177    | Tfunction _ _ ⇒ Some ? (OK ? (Vint i))
178    | _ ⇒ Some ? (Error ?)
179    ]
180  | Tfunction _ _ ⇒
181    match ty' with
182    [ Tpointer _ _ ⇒ Some ? (OK ? (Vint i))
183    | Tarray _ _ _ ⇒ Some ? (OK ? (Vint i))
184    | Tfunction _ _ ⇒ Some ? (OK ? (Vint i))
185    | _ ⇒ Some ? (Error ?)
186    ]
187  | _ ⇒ Some ? (Error ?)
188  ]
189| false ⇒ Some ? (Error ?)
190]. nwhd; //; nlapply (eq_spec i zero); nrewrite > c0; #e; nrewrite > e;
191   napply cast_pp_z; //; nqed.
192
193nlet rec exec_cast (m:mem) (v:val) (ty:type) (ty':type) : res (Σv':val. cast m v ty ty' v') ≝
194match v with
195[ Vint i ⇒
196  match ty with
197  [ Tint sz1 si1 ⇒
198    match ty' with
199    [ Tint sz2 si2 ⇒ Some ? (OK ? (Vint (cast_int_int sz2 si2 i)))
200    | Tfloat sz2 ⇒ Some ? (OK ? (Vfloat (cast_float_float sz2 (cast_int_float si1 i))))
201    | Tpointer _ _ ⇒ Some (res val) (r ← try_cast_null m i ty ty';: OK val r) (* XXX: is this ok for non-null values? *)
202    | Tarray _ _ _ ⇒ Some (res val) (r ← try_cast_null m i ty ty';: OK val r) (* XXX: is this ok for non-null values? *)
203    | Tfunction _ _ ⇒ Some (res val) (r ← try_cast_null m i ty ty';: OK val r) (* XXX: is this ok for non-null values? *)
204    | _ ⇒ Some ? (Error ?)
205    ]
206  | Tpointer _ _ ⇒ Some (res val) (r ← try_cast_null m i ty ty';: OK val r) (* XXX: is this ok for non-null values? *)
207  | Tarray _ _ _ ⇒ Some (res val) (r ← try_cast_null m i ty ty';: OK val r) (* XXX: is this ok for non-null values? *)
208  | Tfunction _ _ ⇒ Some (res val) (r ← try_cast_null m i ty ty';: OK val r) (* XXX: is this ok for non-null values? *)
209  | _ ⇒ Some ? (Error ?)
210  ]
211| Vfloat f ⇒
212  match ty with
213  [ Tfloat sz ⇒
214    match ty' with
215    [ Tint sz' si' ⇒ Some ? (OK ? (Vint (cast_int_int sz' si' (cast_float_int si' f))))
216    | Tfloat sz' ⇒ Some ? (OK ? (Vfloat (cast_float_float sz' f)))
217    | _ ⇒ Some ? (Error ?)
218    ]
219  | _ ⇒ Some ? (Error ?)
220  ]
221| Vptr p b ofs ⇒
222  Some ? (
223    p ← match ty with [ Tpointer _ _ ⇒ OK ? something | Tarray _ _ _ ⇒ OK ? something | Tfunction _ _ ⇒ OK ? something | _ ⇒ Error ? ];:
224    s' ← match ty' with [ Tpointer s _ ⇒ OK ? s | Tarray s _ _ ⇒ OK ? s | Tfunction _ _ ⇒ OK ? Code | _ ⇒ Error ? ];:
225    if is_pointer_compat (block_space m b) s'
226    then OK ? (Vptr s' b ofs)
227    else Error ?)
228  (* XXX: maybe should allow some Tint? *)
229| _ ⇒ Some ? (Error ?)
230]. nwhd; //;
231##[ ##1,2,3,4,5,6: napply sig_bind_OK; #v'; #H; ndestruct; napply H;
232##| napply bind_OK; #u1 tyok;
233    napply bind_OK; #s' es';
234    ncut (type_pointable ty);
235    ##[ ncases ty in tyok ⊢ %; //;
236      ##[ #e; ##| ##3,6: #a e; ##| ##2,4,5: #a b e; ##] nwhd in e:(??%?); ndestruct;
237    ##| ncut (type_space ty' s');
238      ##[ ncases ty' in es' ⊢ %; ##[ #e; ##| ##3,9: #a e; ##| ##2,4,6,7,8: #a b e; ##| #a b c e; ##]
239          nwhd in e:(??%?); ndestruct; //;
240      ##| #Hty' Hty;
241          nwhd in match (is_pointer_compat ??) in ⊢ %;
242          ncases (pointer_compat_dec (block_space m c1) s'); #Hcompat;
243          nwhd; /2/;
244      ##]
245    ##]
246##] nqed.
247
248ndefinition load_value_of_type' ≝
249λty,m,l. match l with [ mk_pair pl ofs ⇒ match pl with [ mk_pair psp loc ⇒
250  load_value_of_type ty m psp loc ofs ] ].
251
252(* To make the evaluation of bare lvalue expressions invoke exec_lvalue with
253   a structurally smaller value, we break out the surrounding Expr constructor
254   and use exec_lvalue'. *)
255
256nlet rec exec_expr (ge:genv) (en:env) (m:mem) (e:expr) on e : res (Σr:val. eval_expr ge en m e r) ≝
257match e with
258[ Expr e' ty ⇒
259  match e' with
260  [ Econst_int i ⇒ Some ? (OK ? (Vint i))
261  | Econst_float f ⇒ Some ? (OK ? (Vfloat f))
262  | Evar _ ⇒ Some ? (
263      l ← exec_lvalue' ge en m e' ty;:
264      opt_to_res ? (load_value_of_type' ty m l))
265  | Ederef _ ⇒ Some ? (
266      l ← exec_lvalue' ge en m e' ty;:
267      opt_to_res ? (load_value_of_type' ty m l))
268  | Efield _ _ ⇒ Some ? (
269      l ← exec_lvalue' ge en m e' ty;:
270      opt_to_res ? (load_value_of_type' ty m l))
271  | Eaddrof a ⇒ Some ? (
272      〈pl, ofs〉 ← exec_lvalue ge en m a;:
273      OK ? (match pl with [ mk_pair pcl loc ⇒ Vptr pcl loc ofs ]))
274  | Esizeof ty' ⇒ Some ? (OK ? (Vint (repr (sizeof ty'))))
275  | Eunop op a ⇒ Some ? (
276      v1 ← exec_expr ge en m a;:
277      opt_to_res ? (sem_unary_operation op v1 (typeof a)))
278  | Ebinop op a1 a2 ⇒ Some ? (
279      v1 ← exec_expr ge en m a1;:
280      v2 ← exec_expr ge en m a2;:
281      opt_to_res ? (sem_binary_operation op v1 (typeof a1) v2 (typeof a2) m))
282  | Econdition a1 a2 a3 ⇒ Some ? (
283      v ← exec_expr ge en m a1;:
284      b ← bool_of_val_3 v (typeof a1);:
285      match b return λ_.res val with [ true ⇒ (exec_expr ge en m a2) | false ⇒ (exec_expr ge en m a3) ])
286(*      if b then exec_expr ge en m a2 else exec_expr ge en m a3)*)
287  | Eorbool a1 a2 ⇒ Some ? (
288      v1 ← exec_expr ge en m a1;:
289      b1 ← bool_of_val_3 v1 (typeof a1);:
290      match b1 return λ_.res val with [ true ⇒ OK ? Vtrue | false ⇒
291        v2 ← exec_expr ge en m a2;:
292        b2 ← bool_of_val_3 v2 (typeof a2);:
293        OK ? (of_bool b2) ])
294  | Eandbool a1 a2 ⇒ Some ? (
295      v1 ← exec_expr ge en m a1;:
296      b1 ← bool_of_val_3 v1 (typeof a1);:
297      match b1 return λ_.res val with [ true ⇒
298        v2 ← exec_expr ge en m a2;:
299        b2 ← bool_of_val_3 v2 (typeof a2);:
300        OK ? (of_bool b2)
301      | false ⇒ OK ? Vfalse ])
302  | Ecast ty' a ⇒ Some ? (
303      v ← exec_expr ge en m a;:
304      exec_cast m v (typeof a) ty')
305  ]
306]
307and exec_lvalue' (ge:genv) (en:env) (m:mem) (e':expr_descr) (ty:type) on e' : res (Σr:memory_space × block × int. eval_lvalue ge en m (Expr e' ty) (\fst (\fst r)) (\snd (\fst r)) (\snd r)) ≝
308  match e' with
309  [ Evar id ⇒
310      match (get … id en) with
311      [ None ⇒ Some ? (〈sp,l〉 ← opt_to_res ? (find_symbol ? ? ge id);: OK ? 〈〈sp,l〉,zero〉) (* global *)
312      | Some loc ⇒ Some ? (OK ? 〈〈Any,loc〉,zero〉) (* local *)
313      ]
314  | Ederef a ⇒ Some ? (
315      v ← exec_expr ge en m a;:
316      match v with
317      [ Vptr sp l ofs ⇒ OK ? 〈〈sp,l〉,ofs〉
318      | _ ⇒ Error ?
319      ])
320  | Efield a i ⇒
321      match (typeof a) with
322      [ Tstruct id fList ⇒ Some ? (
323          〈pl,ofs〉 ← exec_lvalue ge en m a;:
324          delta ← field_offset i fList;:
325          OK ? 〈pl,add ofs (repr delta)〉)
326      | Tunion id fList ⇒ Some ? (
327          〈pl,ofs〉 ← exec_lvalue ge en m a;:
328          OK ? 〈pl,ofs〉)
329      | _ ⇒ Some ? (Error ?)
330      ]
331  | _ ⇒ Some ? (Error ?)
332  ]
333and exec_lvalue (ge:genv) (en:env) (m:mem) (e:expr) on e : res (Σr:memory_space × block × int. eval_lvalue ge en m e (\fst (\fst r)) (\snd (\fst r)) (\snd r)) ≝
334match e with [ Expr e' ty ⇒ exec_lvalue' ge en m e' ty ].
335nwhd;
336##[ ##1,2: //
337##| ##3,4:
338    napply sig_bind_OK; nrewrite > c4; #x; ncases x; #y; ncases y; #sp loc ofs H;
339    napply opt_OK;  #v ev; nwhd in ev:(??%?); napply (eval_Elvalue … H ev);
340##| napply sig_bind2_OK; #x; ncases x; #sp loc ofs H;
341    nwhd; napply eval_Eaddrof; //;
342##| napply sig_bind_OK; #v1 Hv1;
343    napply opt_OK; #v ev;
344    napply (eval_Eunop … Hv1 ev);
345##| napply sig_bind_OK; #v1 Hv1;
346    napply sig_bind_OK; #v2 Hv2;
347    napply opt_OK; #v ev;
348    napply (eval_Ebinop … Hv1 Hv2 ev);
349##| napply sig_bind_OK; #v Hv;
350    napply sig_bind_OK; #v' Hv';
351    napply (eval_Ecast … Hv Hv');
352##| napply sig_bind_OK; #vb Hvb;
353    napply sig_bind_OK; #b;
354    ncases b; #Hb; napply reinject; #v ev Hv;
355    ##[ napply (eval_Econdition_true … Hvb ? Hv);  napply (bool_of ??? Hb);
356    ##| napply (eval_Econdition_false … Hvb ? Hv);  napply (bool_of ??? Hb);
357    ##]
358##| napply sig_bind_OK; #v1 Hv1;
359    napply sig_bind_OK; #b1; ncases b1; #Hb1;
360    ##[ napply sig_bind_OK; #v2 Hv2;
361        napply sig_bind_OK; #b2 Hb2;
362        napply (eval_Eandbool_2 … Hv1 … Hv2);
363        ##[ napply (bool_of … Hb1); ##| napply Hb2; ##]
364    ##| napply (eval_Eandbool_1 … Hv1); napply (bool_of … Hb1);
365    ##]
366##| napply sig_bind_OK; #v1 Hv1;
367    napply sig_bind_OK; #b1; ncases b1; #Hb1;
368    ##[ napply (eval_Eorbool_1 … Hv1); napply (bool_of … Hb1);
369    ##| napply sig_bind_OK; #v2 Hv2;
370        napply sig_bind_OK; #b2 Hb2;
371        napply (eval_Eorbool_2 … Hv1 … Hv2);
372        ##[ napply (bool_of … Hb1); ##| napply Hb2; ##]
373    ##]
374##| //
375##| napply sig_bind_OK; nrewrite > c5; #x; ncases x; #y; ncases y; #sp l ofs H;
376    napply opt_OK; #v ev; napply (eval_Elvalue … H ev);
377##| //
378##| //
379##| napply opt_bind_OK; #sl; ncases sl; #sp l el; napply eval_Evar_global; /2/;
380##| napply (eval_Evar_local … c3);
381##| napply sig_bind_OK; #v; ncases v; //; #sp l ofs Hv; nwhd;
382    napply eval_Ederef; //
383##| ##19,20,21,22,23,24,25,26,27,28,29,30,31,32: //
384##| napply sig_bind2_OK; #x; ncases x; #sp l ofs H;
385    napply bind_OK; #delta Hdelta;
386    napply (eval_Efield_struct … H c5 Hdelta);
387##| napply sig_bind2_OK; #x; ncases x; #sp l ofs H;
388    napply (eval_Efield_union … H c5);
389##| //
390##] nqed.
391
392(* TODO: Can we do this sensibly with a map combinator? *)
393nlet rec exec_exprlist (ge:genv) (e:env) (m:mem) (l:list expr) on l : res (Σvl:list val. eval_exprlist ge e m l vl) ≝
394match l with
395[ nil ⇒ Some ? (OK ? (nil val))
396| cons e1 es ⇒ Some ? (
397  v ← exec_expr ge e m e1;:
398  vs ← exec_exprlist ge e m es;:
399  OK ? (cons val v vs))
400]. nwhd; //;
401napply sig_bind_OK; #v Hv;
402napply sig_bind_OK; #vs Hvs;
403nnormalize; /2/;
404nqed.
405
406(* Don't really want to use subset rather than sigma here, but can't be bothered
407   with *another* set of coercions. XXX: why do I have to get the recursive
408   call's property manually? *)
409
410nlet rec exec_alloc_variables (en:env) (m:mem) (l:list (ident × type)) on l : { r:env × mem | alloc_variables en m l (\fst r) (\snd r) } ≝
411match l with
412[ nil ⇒ Some ? 〈en, m〉
413| cons h vars ⇒
414  match h with [ mk_pair id ty ⇒
415    match alloc m 0 (sizeof ty) Any with [ mk_pair m1 b1 ⇒
416      match exec_alloc_variables (set … id b1 en) m1 vars with
417      [ sig_intro r p ⇒ r ]
418]]]. nwhd;
419##[ //;
420##| nelim (exec_alloc_variables (set ident ? ? c3 c7 en) c6 c1);
421    #H; nelim H; //; #H0; nelim H0; nnormalize; #en' m' IH;
422napply (alloc_variables_cons … IH); /2/;
423nqed.
424
425(* TODO: can we establish that length params = length vs in advance? *)
426nlet rec exec_bind_parameters (e:env) (m:mem) (params:list (ident × type)) (vs:list val) on params : res (Σm2:mem. bind_parameters e m params vs m2) ≝
427  match params with
428  [ nil ⇒ match vs with [ nil ⇒ Some ? (OK ? m) | cons _ _ ⇒ Some ? (Error ?) ]
429  | cons idty params' ⇒ match idty with [ mk_pair id ty ⇒
430      match vs with
431      [ nil ⇒ Some ? (Error ?)
432      | cons v1 vl ⇒ Some ? (
433          b ← opt_to_res ? (get … id e);:
434          m1 ← opt_to_res ? (store_value_of_type ty m Any b zero v1);:
435          err_eject ?? (exec_bind_parameters e m1 params' vl)) (* FIXME: don't want to have to eject here *)
436      ]
437  ] ].
438nwhd; //;
439napply opt_bind_OK; #b eb;
440napply opt_bind_OK; #m1 em1;
441napply reinject; #m2 em2 Hm2;
442napply (bind_parameters_cons … eb em1 Hm2);
443nqed.
444
445ndefinition is_not_void : ∀t:type. res (Σu:unit. t ≠ Tvoid) ≝
446λt. match t with
447[ Tvoid ⇒ Some ? (Error ?)
448| _ ⇒ Some ? (OK ??)
449]. nwhd; //; @; #H; ndestruct; nqed.
450
451ninductive decide : Type ≝
452| dy : decide | dn : decide.
453
454ndefinition dodecide : ∀P:Prop.∀d.∀p:(match d with [ dy ⇒ P | dn ⇒ ¬P ]).P + ¬P.
455#P d;ncases d;/2/; nqed.
456
457ncoercion decide_inject :
458  ∀P:Prop.∀d.∀p:(match d with [ dy ⇒ P | dn ⇒ ¬P ]).P + ¬P ≝ dodecide
459  on d:decide to ? + (¬?).
460
461ndefinition dodecide2 : ∀P:Prop.∀d.∀p:(match d with [ dy ⇒ P | dn ⇒ True ]).res P.
462#P d; ncases d; nnormalize; #p; ##[ napply (OK ? p); ##| napply Error ##] nqed.
463
464ncoercion decide_inject2 :
465  ∀P:Prop.∀d.∀p:(match d with [ dy ⇒ P | dn ⇒ True ]).res P ≝ dodecide2
466  on d:decide to res ?.
467
468alias id "Tint" = "cic:/matita/c-semantics/Csyntax/type.con(0,2,0)".
469alias id "Tfloat" = "cic:/matita/c-semantics/Csyntax/type.con(0,3,0)".
470ndefinition sz_eq_dec : ∀s1,s2:intsize. (s1 = s2) + (s1 ≠ s2).
471#s1; ncases s1; #s2; ncases s2; /2/; @2; @; #H; ndestruct; nqed.
472ndefinition sg_eq_dec : ∀s1,s2:signedness. (s1 = s2) + (s1 ≠ s2).
473#s1; ncases s1; #s2; ncases s2; /2/; @2; @; #H; ndestruct; nqed.
474ndefinition fs_eq_dec : ∀s1,s2:floatsize. (s1 = s2) + (s1 ≠ s2).
475#s1; ncases s1; #s2; ncases s2; /2/; @2; @; #H; ndestruct; nqed.
476ndefinition ms_eq_dec : ∀s1,s2:memory_space. (s1 = s2) + (s1 ≠ s2).
477#s1; ncases s1; #s2; ncases s2; /2/; @2; @; #H; ndestruct; nqed.
478
479nlet rec assert_type_eq (t1,t2:type) : res (t1 = t2) ≝
480match t1 with
481[ Tvoid ⇒ match t2 with [ Tvoid ⇒ dy | _ ⇒ dn ]
482| Tint sz sg ⇒ match t2 with [ Tint sz' sg' ⇒ match sz_eq_dec sz sz' with [ inl _ ⇒ match sg_eq_dec sg sg' with [ inl _ ⇒ dy | _ ⇒ dn ] | _ ⇒ dn ] | _ ⇒ dn ]
483| Tfloat f ⇒ match t2 with [ Tfloat f' ⇒ match fs_eq_dec f f' with [ inl _ ⇒ dy | _ ⇒ dn ] | _ ⇒ dn ]
484| Tpointer s t ⇒ match t2 with [ Tpointer s' t' ⇒
485    match ms_eq_dec s s' with [ inl _ ⇒
486      match assert_type_eq t t' with [ OK _ ⇒ dy | _ ⇒ dn ] | _ ⇒ dn ] | _ ⇒ dn ]
487| Tarray s t n ⇒ match t2 with [ Tarray s' t' n' ⇒
488    match ms_eq_dec s s' with [ inl _ ⇒
489      match assert_type_eq t t' with [ OK _ ⇒
490        match decidable_eq_Z_Type n n' with [ inl _ ⇒ dy | inr _ ⇒ dn ] | _ ⇒ dn ] | _ ⇒ dn ] | _ ⇒ dn ]
491| Tfunction tl t ⇒ match t2 with [ Tfunction tl' t' ⇒ match assert_typelist_eq tl tl' with [ OK _ ⇒
492    match assert_type_eq t t' with [ OK _ ⇒ dy | _ ⇒ dn ] | _ ⇒ dn ] | _ ⇒ dn ]
493| Tstruct i fl ⇒
494    match t2 with [ Tstruct i' fl' ⇒ match ident_eq i i' with [ inl _ ⇒
495      match assert_fieldlist_eq fl fl' with [ OK _ ⇒ dy | _ ⇒ dn ] | inr _ ⇒ dn ] |  _ ⇒ dn ]
496| Tunion i fl ⇒
497    match t2 with [ Tunion i' fl' ⇒ match ident_eq i i' with [ inl _ ⇒
498      match assert_fieldlist_eq fl fl' with [ OK _ ⇒ dy | _ ⇒ dn ] | _ ⇒ dn ] |  _ ⇒ dn ]
499| Tcomp_ptr i ⇒ match t2 with [ Tcomp_ptr i' ⇒ match ident_eq i i' with [ inl _ ⇒ dy | inr _ ⇒ dn ] | _ ⇒ dn ]
500]
501and assert_typelist_eq (tl1,tl2:typelist) : res (tl1 = tl2) ≝
502match tl1 with
503[ Tnil ⇒ match tl2 with [ Tnil ⇒ dy | _ ⇒ dn ]
504| Tcons t1 ts1 ⇒ match tl2 with [ Tnil ⇒ dn | Tcons t2 ts2 ⇒
505    match assert_type_eq t1 t2 with [ OK _ ⇒
506      match assert_typelist_eq ts1 ts2 with [ OK _ ⇒ dy | _ ⇒ dn ] | _ ⇒ dn ] ]
507]
508and assert_fieldlist_eq (fl1,fl2:fieldlist) : res (fl1 = fl2) ≝
509match fl1 with
510[ Fnil ⇒ match fl2 with [ Fnil ⇒ dy | _ ⇒ dn ]
511| Fcons i1 t1 fs1 ⇒ match fl2 with [ Fnil ⇒ dn | Fcons i2 t2 fs2 ⇒
512    match ident_eq i1 i2 with [ inl _ ⇒
513      match assert_type_eq t1 t2 with [ OK _ ⇒
514        match assert_fieldlist_eq fs1 fs2 with [ OK _ ⇒ dy | _ ⇒ dn ]
515        | _ ⇒ dn ] | _ ⇒ dn ] ]
516].
517(* A poor man's clear, otherwise automation picks up recursive calls without
518   checking that the argument is smaller. *)
519ngeneralize in assert_type_eq;
520ngeneralize in assert_typelist_eq;
521ngeneralize in assert_fieldlist_eq; #avoid1; #_; #avoid2; #_; #avoid3; #_; nwhd; //;
522(* XXX: I have no idea why the first // didn't catch these. *)
523//; //; //; //; //; //; //; //; //;
524nqed.
525
526nlet rec is_is_call_cont (k:cont) : (is_call_cont k) + (¬is_call_cont k) ≝
527match k with
528[ Kstop ⇒ dy
529| Kcall _ _ _ _ ⇒ dy
530| _ ⇒ dn
531]. nwhd; //; @; #H; nelim H; nqed.
532
533nlet rec is_Sskip (s:statement) : (s = Sskip) + (s ≠ Sskip) ≝
534match s with
535[ Sskip ⇒ dy
536| _ ⇒ dn
537].
538##[ //;
539##| ##*: @; #H; ndestruct;
540##] nqed.
541
542(* IO monad *)
543
544(* Interactions are function calls that return a value and do not change
545   the rest of the Clight program's state. *)
546ndefinition io_out ≝ (ident × (list eventval)).
547
548ndefinition do_io : ident → list eventval → IO eventval io_out eventval ≝
549λfn,args. Interact ?? eventval 〈fn,args〉 (λres. Value ?? eventval res).
550
551ndefinition ret: ∀T. T → (IO eventval io_out T) ≝
552λT,x.(Value ?? T x).
553
554(* Checking types of values given to / received from an external function call. *)
555
556ndefinition check_eventval : ∀ev:eventval. ∀ty:typ. res (Σv:val. eventval_match ev ty v) ≝
557λev,ty.
558match ty with
559[ Tint ⇒ match ev with [ EVint i ⇒ Some ? (OK ? (Vint i)) | _ ⇒ Some ? (Error ?) ]
560| Tfloat ⇒ match ev with [ EVfloat f ⇒ Some ? (OK ? (Vfloat f)) | _ ⇒ Some ? (Error ?) ]
561| _ ⇒ Some ? (Error ?)
562]. nwhd; //; nqed.
563
564ndefinition check_eventval' : ∀v:val. ∀ty:typ. res (Σev:eventval. eventval_match ev ty v) ≝
565λv,ty.
566match ty with
567[ Tint ⇒ match v with [ Vint i ⇒ Some ? (OK ? (EVint i)) | _ ⇒ Some ? (Error ?) ]
568| Tfloat ⇒ match v with [ Vfloat f ⇒ Some ? (OK ? (EVfloat f)) | _ ⇒ Some ? (Error ?) ]
569| _ ⇒ Some ? (Error ?)
570]. nwhd; //; nqed.
571
572nlet rec check_eventval_list (vs: list val) (tys: list typ) : res (Σevs:list eventval. eventval_list_match evs tys vs) ≝
573match vs with
574[ nil ⇒ match tys with [ nil ⇒ Some ? (OK ? (nil ?)) | _ ⇒ Some ? (Error ?) ]
575| cons v vt ⇒
576  match tys with
577  [ nil ⇒ Some ? (Error ?)
578  | cons ty tyt ⇒ Some ? (
579    ev ← check_eventval' v ty;:
580    evt ← check_eventval_list vt tyt;:
581    OK ? ((sig_eject ?? ev)::evt))
582  ]
583]. nwhd; //;
584napply sig_bind_OK; #ev Hev;
585napply sig_bind_OK; #evt Hevt;
586nnormalize; /2/;
587nqed.
588
589(* execution *)
590
591ndefinition store_value_of_type' ≝
592λty,m,l,v.
593match l with [ mk_pair pl ofs ⇒
594  match pl with [ mk_pair pcl loc ⇒
595    store_value_of_type ty m pcl loc ofs v ] ].
596
597nlet rec exec_step (ge:genv) (st:state) on st : (IO eventval io_out (Σr:trace × state. step ge st (\fst r) (\snd r))) ≝
598match st with
599[ State f s k e m ⇒
600  match s with
601  [ Sassign a1 a2 ⇒ Some ? (
602    ! l ← exec_lvalue ge e m a1;:
603    ! v2 ← exec_expr ge e m a2;:
604    ! m' ← store_value_of_type' (typeof a1) m l v2;:
605    ret ? 〈E0, State f Sskip k e m'〉)
606  | Scall lhs a al ⇒ Some ? (
607    ! vf ← exec_expr ge e m a;:
608    ! vargs ← exec_exprlist ge e m al;:
609    ! fd ← find_funct ? ? ge vf;:
610    ! p ← err_to_io … (assert_type_eq (type_of_fundef fd) (typeof a));:
611(*
612    ! k' ← match lhs with
613         [ None ⇒ ret ? (Kcall (None ?) f e k)
614         | Some lhs' ⇒
615           ! locofs ← exec_lvalue ge e m lhs';:
616           ret ? (Kcall (Some ? 〈sig_eject ?? locofs, typeof lhs'〉) f e k)
617         ];:
618    ret ? 〈E0, Callstate fd vargs k' m〉)
619*)
620    match lhs with
621         [ None ⇒ ret ? 〈E0, Callstate fd vargs (Kcall (None ?) f e k) m〉
622         | Some lhs' ⇒
623           ! locofs ← exec_lvalue ge e m lhs';:
624           ret ? 〈E0, Callstate fd vargs (Kcall (Some ? 〈sig_eject ?? locofs, typeof lhs'〉) f e k) m〉
625         ])
626  | Ssequence s1 s2 ⇒ Some ? (ret ? 〈E0, State f s1 (Kseq s2 k) e m〉)
627  | Sskip ⇒
628      match k with
629      [ Kseq s k' ⇒ Some ? (ret ? 〈E0, State  f s k' e m〉)
630      | Kstop ⇒
631          match fn_return f with
632          [ Tvoid ⇒ Some ? (ret ? 〈E0, Returnstate Vundef k (free_list m (blocks_of_env e))〉)
633          | _ ⇒ Some ? (Wrong ???)
634          ]
635      | Kcall _ _ _ _ ⇒
636          match fn_return f with
637          [ Tvoid ⇒ Some ? (ret ? 〈E0, Returnstate Vundef k (free_list m (blocks_of_env e))〉)
638          | _ ⇒ Some ? (Wrong ???)
639          ]
640      | Kwhile a s' k' ⇒ Some ? (ret ? 〈E0, State f (Swhile a s') k' e m〉)
641      | Kdowhile a s' k' ⇒ Some ? (
642          ! v ← exec_expr ge e m a;:
643          ! b ← bool_of_val_3 v (typeof a);:
644          match b with
645          [ true ⇒ ret ? 〈E0, State f (Sdowhile a s') k' e m〉
646          | false ⇒ ret ? 〈E0, State f Sskip k' e m〉
647          ])
648      | Kfor2 a2 a3 s' k' ⇒ Some ? (ret ? 〈E0, State f a3 (Kfor3 a2 a3 s' k') e m〉)
649      | Kfor3 a2 a3 s' k' ⇒ Some ? (ret ? 〈E0, State f (Sfor Sskip a2 a3 s') k' e m〉)
650      | Kswitch k' ⇒ Some ? (ret ? 〈E0, State f Sskip k' e m〉)
651      | _ ⇒ Some ? (Wrong ???)
652      ]
653  | Scontinue ⇒
654      match k with
655      [ Kseq s' k' ⇒ Some ? (ret ? 〈E0, State f Scontinue k' e m〉)
656      | Kwhile a s' k' ⇒ Some ? (ret ? 〈E0, State f (Swhile a s') k' e m〉)
657      | Kdowhile a s' k' ⇒ Some ? (
658          ! v ← exec_expr ge e m a;:
659          ! b ← bool_of_val_3 v (typeof a);:
660          match b with
661          [ true ⇒ ret ? 〈E0, State f (Sdowhile a s') k' e m〉
662          | false ⇒ ret ? 〈E0, State f Sskip k' e m〉
663          ])
664      | Kfor2 a2 a3 s' k' ⇒ Some ? (ret ? 〈E0, State f a3 (Kfor3 a2 a3 s' k') e m〉)
665      | Kswitch k' ⇒ Some ? (ret ? 〈E0, State f Scontinue k' e m〉)
666      | _ ⇒ Some ? (Wrong ???)
667      ]
668  | Sbreak ⇒
669      match k with
670      [ Kseq s' k' ⇒ Some ? (ret ? 〈E0, State f Sbreak k' e m〉)
671      | Kwhile a s' k' ⇒ Some ? (ret ? 〈E0, State f Sskip k' e m〉)
672      | Kdowhile a s' k' ⇒ Some ? (ret ? 〈E0, State f Sskip k' e m〉)
673      | Kfor2 a2 a3 s' k' ⇒ Some ? (ret ? 〈E0, State f Sskip k' e m〉)
674      | Kswitch k' ⇒ Some ? (ret ? 〈E0, State f Sskip k' e m〉)
675      | _ ⇒ Some ? (Wrong ???)
676      ]
677  | Sifthenelse a s1 s2 ⇒ Some ? (
678      ! v ← exec_expr ge e m a;:
679      ! b ← bool_of_val_3 v (typeof a);:
680      ret ? 〈E0, State f (if b then s1 else s2) k e m〉)
681  | Swhile a s' ⇒ Some ? (
682      ! v ← exec_expr ge e m a;:
683      ! b ← bool_of_val_3 v (typeof a);:
684      ret ? 〈E0, if b then State f s' (Kwhile a s' k) e m
685                     else State f Sskip k e m〉)
686  | Sdowhile a s' ⇒ Some ? (ret ? 〈E0, State f s' (Kdowhile a s' k) e m〉)
687  | Sfor a1 a2 a3 s' ⇒
688      match is_Sskip a1 with
689      [ inl _ ⇒ Some ? (
690          ! v ← exec_expr ge e m a2;:
691          ! b ← bool_of_val_3 v (typeof a2);:
692          ret ? 〈E0, State f (if b then s' else Sskip) (if b then (Kfor2 a2 a3 s' k) else k) e m〉)
693      | inr _ ⇒ Some ? (ret ? 〈E0, State f a1 (Kseq (Sfor Sskip a2 a3 s') k) e m〉)
694      ]
695  | Sreturn a_opt ⇒
696    match a_opt with
697    [ None ⇒ match fn_return f with
698      [ Tvoid ⇒ Some ? (ret ? 〈E0, Returnstate Vundef (call_cont k) (free_list m (blocks_of_env e))〉)
699      | _ ⇒ Some ? (Wrong ???)
700      ]
701    | Some a ⇒ Some ? (
702        ! u ← is_not_void (fn_return f);:
703        ! v ← exec_expr ge e m a;:
704        ret ? 〈E0, Returnstate v (call_cont k) (free_list m (blocks_of_env e))〉)
705    ]
706  | Sswitch a sl ⇒ Some ? (
707      ! v ← exec_expr ge e m a;:
708      match v with [ Vint n ⇒ ret ? 〈E0, State f (seq_of_labeled_statement (select_switch n sl)) (Kswitch k) e m〉
709                   | _ ⇒ Wrong ??? ])
710  | Slabel lbl s' ⇒ Some ? (ret ? 〈E0, State f s' k e m〉)
711  | Sgoto lbl ⇒
712      match find_label lbl (fn_body f) (call_cont k) with
713      [ Some sk' ⇒ match sk' with [ mk_pair s' k' ⇒ Some ? (ret ? 〈E0, State f s' k' e m〉) ]
714      | None ⇒ Some ? (Wrong ???)
715      ]
716  ]
717| Callstate f0 vargs k m ⇒
718  match f0 with
719  [ Internal f ⇒ Some ? (
720    match exec_alloc_variables empty_env m ((fn_params f) @ (fn_vars f)) with [ mk_pair e m1 ⇒
721      ! m2 ← exec_bind_parameters e m1 (fn_params f) vargs;:
722      ret ? 〈E0, State f (fn_body f) k e m2〉
723    ])
724  | External f argtys retty ⇒ Some ? (
725      ! evargs ← check_eventval_list vargs (typlist_of_typelist argtys);:
726      ! evres ← do_io f evargs;:
727      ! vres ← check_eventval evres (proj_sig_res (signature_of_type argtys retty));:
728      ret ? 〈(Eextcall f evargs evres), Returnstate vres k m〉)
729  ]
730| Returnstate res k m ⇒
731  match k with
732  [ Kcall r f e k' ⇒
733    match r with
734    [ None ⇒
735      match res with
736      [ Vundef ⇒ Some ? (ret ? 〈E0, (State f Sskip k' e m)〉)
737      | _ ⇒ Some ? (Wrong ???)
738      ]
739    | Some r' ⇒
740      match r' with [ mk_pair l ty ⇒
741        Some ? (
742          ! m' ← store_value_of_type' ty m l res;:
743          ret ? 〈E0, (State f Sskip k' e m')〉)
744      ]
745    ]
746  | _ ⇒ Some ? (Wrong ???)
747  ]
748]. nwhd; //;
749##[ nrewrite > c7; napply step_skip_call; //; napply c8;
750##| napply step_skip_or_continue_while; @; //;
751##| napply sig_bindIO_OK; #v Hv;
752    napply sig_bindIO_OK; #b; ncases b; #Hb;
753    ##[ napply (step_skip_or_continue_dowhile_true … Hv);
754      ##[ @; // ##| napply (bool_of … Hb); ##]
755    ##| napply (step_skip_or_continue_dowhile_false … Hv);
756      ##[ @; // ##| napply (bool_of … Hb); ##]
757    ##]
758##| napply step_skip_or_continue_for2; @; //;
759##| napply step_skip_break_switch; @; //;
760##| nrewrite > c11; napply step_skip_call; //; napply c12;
761##| napply sig_bindIO_OK; #x; ncases x; #y; ncases y; #pcl loc ofs Hlval;
762    napply sig_bindIO_OK; #v2 Hv2;
763    napply opt_bindIO_OK; #m' em';
764    nwhd; napply (step_assign … Hlval Hv2 em');
765##| napply sig_bindIO_OK; #vf Hvf;
766    napply sig_bindIO_OK; #vargs Hvargs;
767    napply opt_bindIO_OK; #fd efd;
768    napply bindIO_OK; #ety;
769    ncases c6; nwhd;
770    ##[ napply (step_call_none … Hvf Hvargs efd ety);
771    ##| #lhs';
772        napply sig_bindIO_OK; #x; ncases x; #y; ncases y; #pcl loc ofs Hlocofs;
773        nwhd; napply (step_call_some … Hlocofs Hvf Hvargs efd ety);
774    ##]
775##| napply sig_bindIO_OK; #v Hv;
776    napply sig_bindIO_OK; #b; ncases b; #Hb;
777    ##[ napply (step_ifthenelse_true … Hv); napply (bool_of … Hb);
778    ##| napply (step_ifthenelse_false … Hv); napply (bool_of … Hb)
779    ##]
780##| napply sig_bindIO_OK; #v Hv;
781    napply sig_bindIO_OK; #b; ncases b; #Hb;
782    ##[ napply (step_while_true … Hv); napply (bool_of … Hb);
783    ##| napply (step_while_false … Hv); napply (bool_of … Hb);
784    ##]
785##| nrewrite > c11;
786    napply sig_bindIO_OK; #v Hv;
787    napply sig_bindIO_OK; #b; ncases b; #Hb;
788    ##[ napply (step_for_true … Hv); napply (bool_of … Hb);
789    ##| napply (step_for_false … Hv); napply (bool_of … Hb);
790    ##]
791##| napply step_for_start; //;
792##| napply step_skip_break_switch; @2; //;
793##| napply step_skip_or_continue_while; @2; //;
794##| napply sig_bindIO_OK; #v Hv;
795    napply sig_bindIO_OK; #b; ncases b; #Hb;
796    ##[ napply (step_skip_or_continue_dowhile_true … Hv);
797      ##[ @2; // ##| napply (bool_of … Hb); ##]
798    ##| napply (step_skip_or_continue_dowhile_false … Hv);
799      ##[ @2; // ##| napply (bool_of … Hb); ##]
800    ##]
801##| napply step_skip_or_continue_for2; @2; //
802##| napply step_return_0; napply c9;
803##| napply sig_bindIO_OK; #u Hnotvoid;
804    napply sig_bindIO_OK; #v Hv;
805    nwhd; napply (step_return_1 … Hnotvoid Hv);
806##| napply sig_bindIO_OK; #v; ncases v; //; #n Hv;
807    napply step_switch; //;
808##| napply step_goto; nrewrite < c12; napply c9;
809##| napply extract_subset_pair_io; #e m1 ealloc Halloc;
810    napply sig_bindIO_OK; #m2 Hbind;
811    nwhd; napply (step_internal_function … Halloc Hbind);
812##| napply sig_bindIO_OK; #evs Hevs;
813    napply bindIO_OK; #eres;
814    napply sig_bindIO_OK; #res Hres;
815    nwhd; napply step_external_function; @; ##[ napply Hevs; ##| napply Hres; ##] 
816##| ncases c11; #x; ncases x; #pcl b ofs;
817    napply opt_bindIO_OK; #m' em'; napply step_returnstate_1; nwhd in em':(??%?); //;
818##]
819nqed.
820
821nlet rec make_initial_state (p:program) : IO eventval io_out (Σs:state. initial_state p s) ≝
822  let ge ≝ globalenv Genv ?? p in
823  let m0 ≝ init_mem Genv ?? p in
824  Some ? (
825    ! 〈sp,b〉 ← find_symbol ? ? ge (prog_main ?? p);:
826    ! u ← opt_to_io … (match ms_eq_dec sp Code with [ inl _ ⇒ Some ? something | inr _ ⇒ None ? ]);:
827    ! f ← find_funct_ptr ? ? ge b;:
828    ret ? (Callstate f (nil ?) Kstop m0)).
829nwhd;
830napply opt_bindIO2_OK; #sp b esb;
831napply opt_bindIO_OK; #u ecode;
832napply opt_bindIO_OK; #f ef;
833ncases sp in esb ecode; #esb ecode; nwhd in ecode:(??%%); ##[ ##1,2,3,4: ndestruct (ecode); ##]
834nwhd; napply (initial_state_intro … esb ef);
835nqed.
836
837ndefinition is_final_state : ∀st:state. (∃r. final_state st r) + (¬∃r. final_state st r).
838#st; nelim st;
839##[ #f s k e m; @2; @;*; #r H; ninversion H; #i m e; ndestruct;
840##| #f l k m; @2; @;*; #r H; ninversion H; #i m e; ndestruct;
841##| #v k m; ncases k;
842  ##[ ncases v;
843    ##[ ##2: #i; @1; @ i; //;
844    ##| ##1: @2; @; *;   #r H; ninversion H; #i m e; ndestruct;
845    ##| #f; @2; @; *;   #r H; ninversion H; #i m e; ndestruct;
846    ##| #pcl b of; @2; @; *;   #r H; ninversion H; #i m e; ndestruct;
847    ##]
848  ##| #a b; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
849  ##| ##3,4: #a b c; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
850  ##| ##5,6,8: #a b c d; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
851  ##| #a; @2; @; *; #r H; ninversion H; #i m e; ndestruct;
852  ##]
853##] nqed.
854
855nlet rec exec_steps (n:nat) (ge:genv) (s:state) :
856 IO eventval io_out (Σts:trace×state. star (mk_transrel ?? step) ge s (\fst ts) (\snd ts)) ≝
857match is_final_state s with
858[ inl _ ⇒ Some ? (ret ? 〈E0, s〉)
859| inr _ ⇒
860  match n with
861  [ O ⇒ Some ? (ret ? 〈E0, s〉)
862  | S n' ⇒ Some ? (
863      ! 〈t,s'〉 ← exec_step ge s;:
864      ! 〈t',s''〉 ← exec_steps n' ge s';:
865      ret ? 〈t ⧺ t',s''〉)
866  ]
867]. nwhd; /2/;
868napply sig_bindIO2_OK; #t s' H1;
869napply sig_bindIO2_OK; #t' s'' IH;
870nwhd; napply (star_step … IH); //;
871nqed.
872(*
873nlet rec exec_steps_without_proof (n:nat) (ge:genv) (s:state) :
874 res (trace×state) ≝
875match is_final_state s with
876[ inl _ ⇒ OK ? 〈E0, s〉
877| inr _ ⇒
878  match n with
879  [ O ⇒ OK ? 〈E0, s〉
880  | S n' ⇒
881      〈t,s'〉 ← exec_step ge s;:
882      〈t',s''〉 ← exec_steps_without_proof n' ge s';:
883      OK ? 〈t ⧺ t',s''〉
884  ]
885].
886*)
Note: See TracBrowser for help on using the repository browser.